Основной раздел > Общие вопросы
Подскажите 2ой кликер
(1/1)
Atheas:
Такой вопрос, моно ли как то использовать одновременно 2 кликера (что бы использовать 2 различных скрипта) или 2 скрипта в одном кликере не меняя их через загрузку сценария?
kiril:
можно
SimplY:
--- Quote from: Atheas on September 28, 2023, 09:53:55 PM ---Такой вопрос, моно ли как то использовать одновременно 2 кликера (что бы использовать 2 различных скрипта) или 2 скрипта в одном кликере не меняя их через загрузку сценария?
--- End quote ---
3 варианта:
1) Использование 2-х кликеров:
Для этого просто копируется папка с кликером и в другом кликере меняются настройки горячих клавиш. Например: В первом запуск Alt+A, а в другом Alt+Z.
2) В одном скрипте несколько скриптов, каждый из которых запускается своей клавишей:
--- Code: (clickermann) ---$check = 0
WHILE($check = 0)
IF(ISKEYDOWN(#CTRL)=1)
WHILE(ISKEYDOWN(#CTRL)=1)
END_CYC
$check = 1
ELSE
IF(ISKEYDOWN(#ALT)=1)
WHILE(ISKEYDOWN(#ALT)=1)
END_CYC
$check = 2
ELSE
IF(ISKEYDOWN(04)=1)
WHILE(ISKEYDOWN(04)=1)
END_CYC
$check = 3
ELSE
WAITMS(20)
END_IF
END_IF
END_IF
END_CYC
IF($check = 1) // Если нажата CTRL
// Первый скрипт
LOGWRITE ("1")
END_IF
IF($check = 2) // Если нажата ALT
// Второй скрипт
LOGWRITE ("2")
END_IF
IF($check = 3) // Если нажата средняя клавиша мыши
// Третий скрипт
LOGWRITE ("3")
END_IF
--- End code ---
3) В одном скрипте несколько скриптов, каждый из которых запускается своей горячей комбинаций клавиш:
Ребята на форуме подсказали интересный скрипт.
--- Code: (clickermann) ---THREAD(th1, 0)
//сюда ставишь первый сценарий
LOGWRITE("Сценарий 1 завершился")
$status1 = 0
SETTHREAD(th1, 2) // сценарий останавливается после прохода
END_THREAD
THREAD(th2, 0)
//сюда ставишь второй сценарий
LOGWRITE("Сценарий 2 завершился")
$status2 = 0
SETTHREAD(th2, 2)
END_THREAD
THREAD(th3, 0)
//сюда ставишь третий сценарий
LOGWRITE("Сценарий 3 завершился")
$status3 = 0
SETTHREAD(th3, 2)
END_THREAD
//~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
IF(ISKEYDOWN(#ALT) & ISKEYDOWN(#Z))
$status1 = $status1 ^ 1
IF($status1)
SETTHREAD(th1, 1)
LOGWRITE("Сценарий 1 запущен")
ELSE
SETTHREAD(th1, 0) // или код 2 если нужен перезапуск
LOGWRITE("Сценарий 1 остановлен")
END_IF
WHILE(ISKEYDOWN(#ALT) & ISKEYDOWN(#Z))
WAITMS(10)
END_CYC
END_IF
IF(ISKEYDOWN(#ALT) & ISKEYDOWN(#A))
$status2 = $status2 ^ 1
IF($status2)
SETTHREAD(th2, 1)
LOGWRITE("Сценарий 2 запущен")
ELSE
SETTHREAD(th2, 0) // или код 2 если нужен перезапуск
LOGWRITE("Сценарий 2 остановлен")
END_IF
WHILE(ISKEYDOWN(#ALT) & ISKEYDOWN(#A))
WAITMS(10)
END_CYC
END_IF
IF(ISKEYDOWN(#ALT) & ISKEYDOWN(#2))
$status3 = $status3 ^ 1
IF($status3)
SETTHREAD(th3, 1)
LOGWRITE("Сценарий 3 запущен")
ELSE
SETTHREAD(th3, 0) // или код 2 если нужен перезапуск
LOGWRITE("Сценарий 3 остановлен")
END_IF
WHILE(ISKEYDOWN(#ALT) & ISKEYDOWN(#2))
WAITMS(10)
END_CYC
END_IF
--- End code ---
Но в двух последних вариантах кликер изначально должен быть запущен.
Navigation
[0] Message Index
Go to full version