Автокликер Clickermann :: Форум

Основной раздел => Общие вопросы => Topic started by: Enot on August 13, 2014, 01:27:55 PM

Title: Поиск сайта по выдаче яндекса
Post by: Enot on August 13, 2014, 01:27:55 PM
добрый день, пожалуйста помогите, как написать в кликермане, чтобы лазил на яндексе по определенному поисковому запросу, если на одной странице не находил определенною картинку ( http://autonew16.ru/images/favicon.ico ) то переходил бы на следующий страницу и продолжал искать пока не найдет. как сделать помогите пожалуйста
Title: Re: Поиск сайта по выдаче яндекса
Post by: Dampil on August 13, 2014, 03:38:23 PM
могу ошибаться, но...
Алгоритм примерно следующий: ввод запроса(тут можно и руками), далее - левый клик по первым координатам, в цикле: getscreen, поиск картинки на открытой части страницы, проверка на конец страницы, пролистывание посылом pgdown; если конец страницы достигнут, break(так, вроде для выхода), возврат к странице яндеха, перевод курсора на N пихелей ниже, повтор алгоритма
Title: Re: Поиск сайта по выдаче яндекса
Post by: Vint on August 13, 2014, 04:05:35 PM
Как то так:
Code: (clickermann) [Select]
#name "favicon search in Yandex"
// Author: Vint
// Version: 1.0 (13.08.2014)

$zapros = "лунная афёра"
$page_all = 10   // просматривать страниц
$brawser = "firefox.exe"

//==============================================================================
SUB(close) //===================================================================
   KEYDOWN (#CTRL)
   WAITMS (50)
   KEYDOWN (#W)
   WAITMS (50)
   KEYUP (#W)
   KEYUP (#CTRL)
   WAITMS(500)
END_SUB

//==============================================================================

LOGCLEAR
$hwnd = WNDFIND("Mozilla Firefox")
IF($hwnd > 0)
   EXECUTE("firefox.exe", "yandex.ru")      //запуск Мозилы
   WAIT(3)
END_IF

$zapros = STRREPLACE ($zapros, " ", "%20")   // лечение пробелов
FOR($page=0, $page<$page_all)
   $param = STRCONCAT("yandex.ru/yandsearch?lr=213&text=", $zapros, "&p=", $page)
   LOGWRITE ("Страница ", $page)
   //LOGWRITE ($param)
   EXECUTE($brawser, $param)   //открываем страницу
   WAITMS(1500)
   LCLICK(5,500)
   WAITMS(50)
   
   $var = 1
   WHILE($var = 1)
      //LOGWRITE ("ищем...")
      GETSCREEN
      IF_PICTURE_IN (100,0,$_xmax-35,$_ymax, "favicon.bmp") // 16777215
         LOGWRITE ("Найдено на странице ", $page)
         HINTPOPUP(STRCONCAT("страница ", $page), "Найдено!")
         LOGSHOW (1,$_xmax-335,28) // отображение окна лога
         WNDSIZE(WNDFIND("Clickermann - Лог"),336,260) // изменения размеров окна лога
         HALT
      END_IF
     
      // мотаем ниже
      $hash1 = PXLCRC (220,180,230,800)
      WHEELDOWN(6)
      WAITMS(100)
      GETSCREEN
      $hash2 = PXLCRC (220,180,230,800)
     
      IF($hash1 = $hash2)
         close() // закрываем вкладку
         $var = 0
      END_IF
      WAITMS(500)
   END_CYC
END_CYC
LOGWRITE ("Ничего не найдено. Пройдено ", $page_all, " страниц")
HINTPOPUP(STRCONCAT("Не найдено на ", $page_all, " стр."), "Не найдено")
LOGSHOW (1,$_xmax-335,28) // отображение окна лога
WNDSIZE(WNDFIND("Clickermann - Лог"),336,260) // изменения размеров окна лога
HALT
Title: Re: Поиск сайта по выдаче яндекса
Post by: Enot on August 13, 2014, 05:25:30 PM
спасибо большое. а как потом сделать чтобы он на сайт заходил найденый
Title: Re: Поиск сайта по выдаче яндекса
Post by: Vint on August 13, 2014, 05:43:07 PM
перед 48 строкой
кликнуть ниже и правее найденной
Code: (clickermann) [Select]
LCLICK($_return1+50, $_return2+10)
Title: Re: Поиск сайта по выдаче яндекса
Post by: Enot on August 13, 2014, 05:47:17 PM
спасибо большое
Title: Re: Поиск сайта по выдаче яндекса
Post by: Enot on August 14, 2014, 10:01:24 AM
помогите пожалуйста. этот скрипт нашел мне саит и зашел к нему, у меня не получается чтобы запускался второи скрипт который будет уже выполнять другую команду
Code: (clickermann) [Select]
#name "favicon search in Yandex"
// Author: Vint
// Version: 1.0 (13.08.2014)

$zapros = "тюнинг Мазда6"
$page_all = 10   // просматривать страниц
$brawser = "firefox.exe"

//==============================================================================
SUB(close) //===================================================================
   KEYDOWN (#CTRL)
   WAITMS (50)
   KEYDOWN (#W)
   WAITMS (50)
   KEYUP (#W)
   KEYUP (#CTRL)
   WAITMS(500)
END_SUB

//==============================================================================

LOGCLEAR
$hwnd = WNDFIND("Mozilla Firefox")
IF($hwnd > 0)
   EXECUTE("firefox.exe", "yandex.ru")      //запуск Мозилы
   WAIT(3)
END_IF

$zapros = STRREPLACE ($zapros, " ", "%20")   // лечение пробелов
FOR($page=0, $page<$page_all)
   $param = STRCONCAT("yandex.ru/yandsearch?lr=213&text=", $zapros, "&p=", $page)
   LOGWRITE ("Страница ", $page)
   //LOGWRITE ($param)
   EXECUTE($brawser, $param)   //открываем страницу
   WAITMS(1500)
   LCLICK(5,500)
   WAITMS(50)
   
   $var = 1
   WHILE($var = 1)
      //LOGWRITE ("ищем...")
      GETSCREEN
      IF_PICTURE_IN (100,0,$_xmax-35,$_ymax, "favicon.bmp") // 16777215
         LOGWRITE ("Найдено на странице ", $page)
         HINTPOPUP(STRCONCAT("страница ", $page), "Найдено!")
         LOGSHOW (1,$_xmax-335,28) // отображение окна лога
         WNDSIZE(WNDFIND("Clickermann - Лог"),336,260) // изменения размеров окна лога
LCLICK($_return1+50, $_return2+10)

EXECUTE("1.cms")      //запуск лазилки
WAITMS(1000)
  LCLICK(564 , 407)
         HALT

      END_IF
     
      // мотаем ниже
      $hash1 = PXLCRC (220,180,230,800)
      WHEELDOWN(6)
      WAITMS(100)
      GETSCREEN
      $hash2 = PXLCRC (220,180,230,800)
     
      IF($hash1 = $hash2)
         close() // закрываем вкладку
         $var = 0
      END_IF
      WAITMS(500)
   END_CYC
END_CYC
LOGWRITE ("Ничего не найдено. Пройдено ", $page_all, " страниц")
HINTPOPUP(STRCONCAT("Не найдено на ", $page_all, " стр."), "Не найдено")
LOGSHOW (1,$_xmax-335,28) // отображение окна лога
WNDSIZE(WNDFIND("Clickermann - Лог"),336,260) // изменения размеров окна лога
HALT
Title: Re: Поиск сайта по выдаче яндекса
Post by: Vint on August 14, 2014, 10:40:24 AM
Ты так и будешь по чайной ложке выдавать?
Сначала был вопрос просто "... продолжал искать пока не найдет".
Естественно я делал с учётом задачи и на этом остановил.
Потом добавилось "открыть найденное".
Теперь "второй скрипт". Что делает этот второй скрипт? Что нужно делать после его завершения? Остановить?... Возвращаться к поиску и искать новый запрос?... Возвращаться к поиску и искать другой сайт?...
Всё это нужно знать сразу, чтобы не переписывать по 100 раз.

Ты озвучь всю задачу от начала и до конца. По частям нужно тому, кто сам доделывает. Ты же не доделываешь судя по второму вопросу..
Title: Re: Поиск сайта по выдаче яндекса
Post by: Enot on August 14, 2014, 12:05:08 PM
я хочу написать бот который будет поднимать сайт в поисковой системе. я уже сделал что кликерман менял IP адреса после этого он
находит нужный сайт и заходит в него. теперь вы мне команду написали хочу чтобы как он сайт найдет и зайдет в него он включал другой кликерман а там у него будет задача другая. как сделать чтобы кликерман закрыл эту задачу ( после того как  он найдет сайт ) и включал другой скрипт у которой будет другая задача
Title: Re: Поиск сайта по выдаче яндекса
Post by: Vint on August 14, 2014, 12:52:26 PM
А зачем такие сложности? Почему нельзя продолжить в этом же скрипте?
Можно для удобства всё выделить в подпрограммы "поиск", "обработка".

Когда отработает второй скрипт что будет делать?
Title: Re: Поиск сайта по выдаче яндекса
Post by: Enot on August 14, 2014, 12:56:34 PM

Когда отработает второй скрипт что будет делать?

*****
вернется на самый первый скрипт где  произойдет смена айпи адреса. и программа все сначала будет искать сайт
Title: Re: Поиск сайта по выдаче яндекса
Post by: Vint on August 14, 2014, 01:16:10 PM
Code: (clickermann) [Select]
#name "favicon search in Yandex"
// Author: Vint
// Version: 1.1 (14.08.2014)

$zapros = "лунная афёра"
$page_all = 10   // просматривать страниц
$brawser = "firefox.exe"


//==============================================================================
SUB(close) //===================================================================
   KEYDOWN (#CTRL)
   WAITMS (50)
   KEYDOWN (#W)
   WAITMS (50)
   KEYUP (#W)
   KEYUP (#CTRL)
   WAITMS(500)
END_SUB

//==============================================================================
SUB(IP) //======================================================================
   // здесь скрипт смены IP
END_SUB

//==============================================================================
SUB(actions) //=================================================================
   // здесь скрипт действий на найденных страницах
END_SUB

//==============================================================================
SUB(find) //== Поиск в выдаче яндекса ==========================================
   $hwnd = WNDFIND("Mozilla Firefox")
   IF($hwnd > 0)
      EXECUTE("firefox.exe", "yandex.ru")      //запуск Мозилы
      WAIT(3)
   END_IF
   
   $find = 0
   $zapros = STRREPLACE ($zapros, " ", "%20")   // лечение пробелов
   FOR($page=0, $page<$page_all)
      $param = STRCONCAT("yandex.ru/yandsearch?lr=213&text=", $zapros, "&p=", $page)
      LOGWRITE ("Страница ", $page)
      //LOGWRITE ($param)
      EXECUTE($brawser, $param)   //открываем страницу
      WAITMS(1500)
      LCLICK(5,500)
      WAITMS(50)
     
      $var = 1
      WHILE($var = 1)
         //LOGWRITE ("ищем...")
         GETSCREEN
         IF_PICTURE_IN (100,0,$_xmax-35,$_ymax, "favicon.bmp") // 16777215
            LOGWRITE ("Найдено на странице ", $page)
            HINTPOPUP(STRCONCAT("страница ", $page), "Найдено!")
            //LOGSHOW (1,$_xmax-335,28) // отображение окна лога
            //WNDSIZE(WNDFIND("Clickermann - Лог"),336,260) // изменения размеров окна лога
            $run_X = $_return1+50
            $run_Y = $_return2+10
            $find = 1
            $var = 0
            $page = $page_all
            //HALT
         END_IF
         
         IF($var = 1)
            // мотаем ниже
            $hash1 = PXLCRC (220,180,230,800)
            WHEELDOWN(6)
            WAITMS(100)
            GETSCREEN
            $hash2 = PXLCRC (220,180,230,800)
           
            IF($hash1 = $hash2)
               close() // закрываем вкладку
               $var = 0
            END_IF
            WAITMS(500)
         END_IF
      END_CYC
   END_CYC
END_SUB

//==============================================================================


//  --- START ---

LOGCLEAR
WHILE(1) // основной цикл скрипта
   IP() // меняем IP
   find() // ищем сайт
   
   IF($find = 1) // нашли
      LCLICK($run_X, $run_Y) // открываем сайт
      WAITMS(2000)
      actions() // обрабатываем
   ELSE //не нашли
      LOGWRITE ("Ничего не найдено. Пройдено ", $page_all, " страниц")
      HINTPOPUP(STRCONCAT("Не найдено на ", $page_all, " стр."), "Не найдено")
      HALT
   END_IF
END_CYC

HALT
Title: Re: Поиск сайта по выдаче яндекса
Post by: Enot on August 14, 2014, 01:18:57 PM
Спасибо Vint) огромное спасибо) как сайт раскручу буду должен))
Title: Re: Поиск сайта по выдаче яндекса
Post by: Enot on August 14, 2014, 01:25:43 PM
а можно узнать какой это язык программирование чтобы книшку почитать ?
Title: Re: Поиск сайта по выдаче яндекса
Post by: Vint on August 14, 2014, 01:44:04 PM
Quote from: Enot on August 14, 2014, 01:25:43 PM
а можно узнать какой это язык программирование чтобы книшку почитать ?
Местный, авторский Johnny (http://crapware.aidf.org/forum/index.php?action=profile;u=1).
Си подобно-неподобный.
Основные конструкции везде почти одинаковые, так что здесь без разницы.

Открой справку и читай подряд. Потом пиши скрипт и читай не подряд.
Title: Re: Поиск сайта по выдаче яндекса
Post by: Enot on August 14, 2014, 05:12:57 PM
мне все равно нужен скрипт этот которой будет другой скрипт открывать напиши пожалуйста
Title: Re: Поиск сайта по выдаче яндекса
Post by: Vint on August 15, 2014, 08:59:06 AM
Не буду.

Ну запустил ты новый, этот что будет делать? Как он узнает что тот отработал?
Если этот заменять новым по LOAD, а из того опять запускать этот, то это маразм.
Делай нормально и будет нормально работать.

Не поверю, что очень тяжело вставить свой второй кусок на указанное место.
Title: Re: Поиск сайта по выдаче яндекса
Post by: Atas on August 15, 2014, 09:54:27 AM
Может быть инклуды подойдут? Много скриптов в одном. Ничем не хуже поочередного запуска скриптов, даже лучше.

Справка по языку сценариев; актуально для версии: 4.10 (build 000); дата сборки: 03.04.2014 => Основы (см. в таблице)
Quote
#include

Вставляет в это место содержимое текстового файла из папки проекта. Это позволяет "прятать" объемный код, повышая таким образом читаемость скрипта.

Пример: #include "mylib.cms"

Code: (clickermann) [Select]
#include "1_script.cms" // Вызываем первый скрипт

#include "2_script.cms" // После того, как отработает первый скрипт, вызывается второй и т.д.

#include "3_script.cms" //  и т.д.

HALT
Другое дело, если требуется запустить одновременно несколько процессов Clickermann.exe ...
Title: Re: Поиск сайта по выдаче яндекса
Post by: Vint on August 15, 2014, 09:57:14 AM
А в инклюдах сабы починили? А то у меня в голове отложилось, что не работает и не стал предлагать.
Title: Re: Поиск сайта по выдаче яндекса
Post by: Atas on August 15, 2014, 10:10:22 AM
Quote
А в инклюдах сабы починили?
Если честно, про это я не в курсе.  :-[ Инклюды не использую, нет надобности пока просто, да и проблема с одновременным открытием двух редакторов присутствует. Удобно сделано конечно, что можно открыть и основной скрипт и инклюд одновременно и редактировать их. Но потом, чтобы запустить любой из них требуется сначала закрыть оба, иначе не запустится.
Clickermann v4.10 (build 003) | M$ Windows 7 SP1 (x64)
Title: Re: Поиск сайта по выдаче яндекса
Post by: aden on August 15, 2014, 04:00:35 PM
Quote from: Vint on August 15, 2014, 09:57:14 AM
А в инклюдах сабы починили? А то у меня в голове отложилось, что не работает и не стал предлагать.
я пользуюсь без проблем
Title: Re: Поиск сайта по выдаче яндекса
Post by: Enot on August 19, 2014, 10:46:24 AM
добрый день! как сделать в кликермане  чтобы прокси он сам менял http://liwihelp.ru/internet-2/kak-smenit-ip-adres-cherez-proksi-server-v-firefox.html в кликармане вел прокси даные и он сам все остальное делал?
Title: Re: Поиск сайта по выдаче яндекса
Post by: Atas on August 19, 2014, 01:34:25 PM
Можно просто начинать интернет-серфинг с бесплатных сервисов-анонимайзеров, например:
Хамелеон - Анонимайзер (http://cameleo.ru/) или ДайДоступ (http://daidostup.ru/).
Они предоставляют свою строку ввода веб-адреса, в которую Clickermann может вписывать нужный вам адрес.
Анонимайзер сам подберет оптимальный прокси.
Это только как вариант.
Title: Re: Поиск сайта по выдаче яндекса
Post by: Enot on August 19, 2014, 02:19:54 PM
Quote from: Atas on August 19, 2014, 01:34:25 PM
Можно просто начинать интернет-серфинг с бесплатных сервисов-анонимайзеров, например:
Хамелеон - Анонимайзер (http://cameleo.ru/) или ДайДоступ (http://daidostup.ru/).
Они предоставляют свою строку ввода веб-адреса, в которую Clickermann может вписывать нужный вам адрес.
Анонимайзер сам подберет оптимальный прокси.
Это только как вариант.


мне так не подходит мне нужно с одного региона.
в кликемане вел прохи и он с этими проксими лазил
Title: Re: Поиск сайта по выдаче яндекса
Post by: Atas on August 19, 2014, 09:24:01 PM
Тогда можно редактировать файл настроек Firefox "prefs.js".
Который лежит в папке профиля C:\Users\Имя_Пользователя\AppData\Roaming\Mozilla\Firefox\Profiles\блаблабла\

Там есть такие строки (добавил комментарии):
Code: (javascript) [Select]
user_pref("network.proxy.type", 0); // 1 - включен прокси; 0 - выключен (эта строка в файле есть всегда)
user_pref("network.proxy.share_proxy_settings", true); // Флаг использования этого прокси-сервера для всех протоколов (строка есть только когда опция включена)
Code: (javascript) [Select]
user_pref("network.proxy.ftp", "192.168.0.12");
user_pref("network.proxy.ftp_port", 3122);
user_pref("network.proxy.http", "192.168.0.12");
user_pref("network.proxy.http_port", 3122);
user_pref("network.proxy.socks", "192.168.0.12");
user_pref("network.proxy.socks_port", 3122);
user_pref("network.proxy.ssl", "192.168.0.12");
user_pref("network.proxy.ssl_port", 3122); // Все эти строки появляются в файле настроек, только тогда, когда прописан прокси
В данном примере Firefox настроен на соединение через прокси 192.168.0.12, порт 3122.
Firefox придется перезапускать, каждый раз после редактировании файла.
Title: Re: Поиск сайта по выдаче яндекса
Post by: Enot on August 19, 2014, 09:26:56 PM
Quote from: Atas on August 19, 2014, 09:24:01 PM
Тогда можно редактировать файл настроек Firefox "prefs.js".
Который лежит в папке профиля C:\Users\Имя_Пользователя\AppData\Roaming\Mozilla\Firefox\Profiles\блаблабла\

Там есть такие строки (добавил комментарии):
Code: (javascript) [Select]
user_pref("network.proxy.type", 0); // 1 - включен прокси; 0 - выключен (эта строка в файле есть всегда)
user_pref("network.proxy.share_proxy_settings", true); // Флаг использования этого прокси-сервера для всех протоколов (строка есть только когда опция включена)
Code: (javascript) [Select]
user_pref("network.proxy.ftp", "192.168.0.12");
user_pref("network.proxy.ftp_port", 3122);
user_pref("network.proxy.http", "192.168.0.12");
user_pref("network.proxy.http_port", 3122);
user_pref("network.proxy.socks", "192.168.0.12");
user_pref("network.proxy.socks_port", 3122);
user_pref("network.proxy.ssl", "192.168.0.12");
user_pref("network.proxy.ssl_port", 3122); // Все эти строки появляются в файле настроек, только тогда, когда прописан прокси
В данном примере Firefox настроен на соединение через прокси 192.168.0.12, порт 3122.
Firefox придется перезапускать, каждый раз после редактировании файла.

мне надо чтобы кликерман все это сам делал
Title: Re: Поиск сайта по выдаче яндекса
Post by: Atas on August 19, 2014, 10:00:53 PM
Можно попробовать сделать по другому.
Если в Firefox в настройках соединения установить - "Использовать системные настройки прокси", а в Internet Explorer эти самые настройки прописать и применить, то Firefox применяет их без перезагрузки. Можно попробовать сделать это с помощью *.reg или *.bat-файлов.
Пробовать надо...
Title: Re: Поиск сайта по выдаче яндекса
Post by: Enot on August 19, 2014, 10:13:23 PM
Quote from: Atas on August 19, 2014, 10:00:53 PM
Можно попробовать сделать по другому.
Если в Firefox в настройках соединения установить - "Использовать системные настройки прокси", а в Internet Explorer эти самые настройки прописать и применить, то Firefox применяет их без перезагрузки. Можно попробовать сделать это с помощью *.reg или *.bat-файлов.
Пробовать надо...

#name "favicon search in Yandex"
// Author: Vint
// Version: 1.1 (14.08.2014)
 
Code: (javascript) [Select]
$zapros = "лунная афёра"
$page_all = 10   // просматривать страниц
$brawser = "firefox.exe"
 
 
//==============================================================================
SUB(close) //===================================================================
   KEYDOWN (#CTRL)
   WAITMS (50)
   KEYDOWN (#W)
   WAITMS (50)
   KEYUP (#W)
   KEYUP (#CTRL)
   WAITMS(500)
END_SUB
 
//==============================================================================
SUB(IP) //======================================================================
   // здесь скрипт смены IP
END_SUB
 
//==============================================================================
SUB(actions) //=================================================================
   // здесь скрипт действий на найденных страницах
END_SUB
 
//==============================================================================
SUB(find) //== Поиск в выдаче яндекса ==========================================
   $hwnd = WNDFIND("Mozilla Firefox")
   IF($hwnd > 0)
      EXECUTE("firefox.exe", "yandex.ru")      //запуск Мозилы
      WAIT(3)
   END_IF
 
   $find = 0
   $zapros = STRREPLACE ($zapros, " ", "%20")   // лечение пробелов
   FOR($page=0, $page<$page_all)
      $param = STRCONCAT("yandex.ru/yandsearch?lr=213&text=", $zapros, "&p=", $page)
      LOGWRITE ("Страница ", $page)
      //LOGWRITE ($param)
      EXECUTE($brawser, $param)   //открываем страницу
      WAITMS(1500)
      LCLICK(5,500)
      WAITMS(50)
 
      $var = 1
      WHILE($var = 1)
         //LOGWRITE ("ищем...")
         GETSCREEN
         IF_PICTURE_IN (100,0,$_xmax-35,$_ymax, "favicon.bmp") // 16777215
            LOGWRITE ("Найдено на странице ", $page)
            HINTPOPUP(STRCONCAT("страница ", $page), "Найдено!")
            //LOGSHOW (1,$_xmax-335,28) // отображение окна лога
            //WNDSIZE(WNDFIND("Clickermann - Лог"),336,260) // изменения размеров окна лога
            $run_X = $_return1+50
            $run_Y = $_return2+10
            $find = 1
            $var = 0
            $page = $page_all
            //HALT
         END_IF
 
         IF($var = 1)
            // мотаем ниже
            $hash1 = PXLCRC (220,180,230,800)
            WHEELDOWN(6)
            WAITMS(100)
            GETSCREEN
            $hash2 = PXLCRC (220,180,230,800)
 
            IF($hash1 = $hash2)
               close() // закрываем вкладку
               $var = 0
            END_IF
            WAITMS(500)
         END_IF
      END_CYC
   END_CYC
END_SUB
 
//==============================================================================
 
 
//  --- START ---
 
LOGCLEAR
WHILE(1) // основной цикл скрипта
   IP() // меняем IP
   find() // ищем сайт
 
   IF($find = 1) // нашли
      LCLICK($run_X, $run_Y) // открываем сайт
      WAITMS(2000)
      actions() // обрабатываем
   ELSE //не нашли
      LOGWRITE ("Ничего не найдено. Пройдено ", $page_all, " страниц")
      HINTPOPUP(STRCONCAT("Не найдено на ", $page_all, " стр."), "Не найдено")
      HALT
   END_IF
END_CYC
 
HALT
 [/td]
[/tr]
[/table]

надо скрипт вот это подошел к этому скрипту
Title: Re: Поиск сайта по выдаче яндекса
Post by: Enot on August 20, 2014, 07:48:38 PM
все работает кроме нахождения сайта по картинки( как исправить? а можно сделать чтобы сайт искал не по картинке а по сыке фото фложил

Code: (clickermann) [Select]
#name "favicon search in Yandex"
// Author: Vint
// Version: 1.1 (14.08.2014)
 
$zapros = "Тюнинг Мазда6"
$page_all = 10   // просматривать страниц
$brawser = "firefox.exe"
 
 
//==============================================================================
SUB(close) //===================================================================
   KEYDOWN (#CTRL)
   WAITMS (50)
   KEYDOWN (#W)
   WAITMS (50)
   KEYUP (#W)
   KEYUP (#CTRL)
   WAITMS(500)
END_SUB
 
//==============================================================================
SUB(IP) //======================================================================
   // здесь скрипт смены IP
LCLICK(1275,10)
WAIT(3)
LCLICK(1313,154)
LCLICK(1313,154)
WAIT(2)
  lDown(220,56)
move(12,54)
  lUp(12,54)
  keyDown(17)
  keyDown(162)
  keyDown(67)
  keyUp(67)
  keyUp(17)
  keyUp(162)
  keyDown(8)
  keyUp(8)
move(12,56)
move(12,58)
move(12,60)
move(12,62)
move(12,64)
move(12,66)
move(12,68)
move(12,70)
  lDown(12,70)
  lUp(12,70)
  keyDown(8)
  keyUp(8)
LCLICK(805,10) 
LCLICK(595,392)
   $hwnd = WNDFIND("Mozilla Firefox")
   IF($hwnd > 0)
      EXECUTE("firefox.exe", "yandex.ru")      //запуск Мозилы
      WAIT(10)
LCLICK(1309,48)
LCLICK(1335,191)
    lDown(797,282)
  lUp(797,282)
  lDown(797,282)
move(527,284)
  lUp(527,284)
  keyDown(17)
  keyDown(162)
  keyDown(86)
  keyUp(86)
  keyUp(162)
  keyUp(17)
WAIT(1)
LCLICK(625,510)
WAIT(4)
 LCLICK(1309,48)
  WAIT(1)
 LCLICK(1211,90)
 WAIT(2)
 LCLICK(715,90)
   END_IF
END_SUB
 
//==============================================================================
SUB(actions) //=================================================================
   // здесь скрипт действий на найденных страницах
END_SUB
 
//==============================================================================
SUB(find) //== Поиск в выдаче яндекса ==========================================

 
   $find = 0
   $zapros = STRREPLACE ($zapros, " ", "%20")   // лечение пробелов
   FOR($page=0, $page<$page_all)
      $param = STRCONCAT("yandex.ru/yandsearch?lr=213&text=", $zapros, "&p=", $page)
      LOGWRITE ("Страница ", $page)
      //LOGWRITE ($param)
      EXECUTE($brawser, $param)   //открываем страницу
      WAITMS(2500)
      LCLICK(5,500)
      WAITMS(150)
 
      $var = 1
      WHILE($var = 1)
         //LOGWRITE ("ищем...")
         GETSCREEN
         IF_PICTURE_IN (100,0,$_xmax-35,$_ymax, "favicon.bmp") // 16777215
            LOGWRITE ("Найдено на странице ", $page)
            HINTPOPUP(STRCONCAT("страница ", $page), "Найдено!")
            //LOGSHOW (1,$_xmax-335,28) // отображение окна лога
            //WNDSIZE(WNDFIND("Clickermann - Лог"),336,260) // изменения размеров окна лога
            $run_X = $_return1+50
            $run_Y = $_return2+10
            $find = 1
            $var = 0
            $page = $page_all
            //HALT
         END_IF
 
         IF($var = 1)
            // мотаем ниже
            $hash1 = PXLCRC (220,180,230,800)
            WHEELDOWN(6)
            WAITMS(2500)
            GETSCREEN
            $hash2 = PXLCRC (220,180,230,800)
 
            IF($hash1 = $hash2)
               close() // закрываем вкладку
               $var = 0
            END_IF
            WAITMS(1500)
         END_IF
      END_CYC
   END_CYC
END_SUB
 
//==============================================================================
 
 
//  --- START ---
 
LOGCLEAR
WHILE(1) // основной цикл скрипта
   IP() // меняем IP
   find() // ищем сайт
 
   IF($find = 1) // нашли
      LCLICK($run_X, $run_Y) // открываем сайт
      WAITMS(2000)
      actions() // обрабатываем
   ELSE //не нашли
      LOGWRITE ("Ничего не найдено. Пройдено ", $page_all, " страниц")
      HINTPOPUP(STRCONCAT("Не найдено на ", $page_all, " стр."), "Не найдено")
      HALT
   END_IF
END_CYC
 
HALT
 
 как все лежит у меня
https://yadi.sk/d/jVEEBEMBa8ABa
Title: Re: Поиск сайта по выдаче яндекса
Post by: Oraven on August 20, 2014, 08:37:17 PM
Глянул яндекс диск, где "favicon.bmp"?
Для проектов есть папка projects, зачем мусорить скриптами где попало?
Title: Re: Поиск сайта по выдаче яндекса
Post by: Enot on August 20, 2014, 08:41:29 PM
Quote from: Oraven on August 20, 2014, 08:37:17 PM
Глянул яндекс диск, где "favicon.bmp"?
Для проектов есть папка projects, зачем мусорить скриптами где попало?
он там есть просто он открытым состояние показывает там буква а
все переместил в папку projects все равно скрип не ищит сайт по картинке
Title: Re: Поиск сайта по выдаче яндекса
Post by: Vint on August 21, 2014, 07:21:47 AM
Quote from: Enot on August 20, 2014, 07:48:38 PM
все работает кроме нахождения сайта по картинки( как исправить? а можно сделать чтобы сайт искал не по картинке а по сыке...
Так разберись с поиском, на примере простого скрипта. Если не находит одну картинку ты думаешь будет находить другую, более сложную в поиске?
И зачем каждый раз новая тема?

Создай рядом новый скрипт для теста
Code: (clickermann) [Select]
LOGCLEAR
GETSCREEN
IF_PICTURE_IN (0,0,$_xmax,$_ymax, "favicon.bmp")
   LOGWRITE ("Найдено")
   MOVE($_return1,$_return2)
ELSE
   LOGWRITE ("Не найдено")   
END_IF
HALT
Открой браузер на странице с нужной иконкой в выдаче поиска. Открой лог кликера. Запускай скрипт. Что в логе?

У меня всё находит (на XP).
Title: Re: Поиск сайта по выдаче яндекса
Post by: Enot on August 21, 2014, 08:41:35 AM
Quote from: Vint on August 21, 2014, 07:21:47 AM
Quote from: Enot on August 20, 2014, 07:48:38 PM
все работает кроме нахождения сайта по картинки( как исправить? а можно сделать чтобы сайт искал не по картинке а по сыке...
Так разберись с поиском, на примере простого скрипта. Если не находит одну картинку ты думаешь будет находить другую, более сложную в поиске?
И зачем каждый раз новая тема?

Создай рядом новый скрипт для теста
Code: (clickermann) [Select]
LOGCLEAR
GETSCREEN
IF_PICTURE_IN (0,0,$_xmax,$_ymax, "favicon.bmp")
   LOGWRITE ("Найдено")
   MOVE($_return1,$_return2)
ELSE
   LOGWRITE ("Не найдено")   
END_IF
HALT
Открой браузер на странице с нужной иконкой в выдаче поиска. Открой лог кликера. Запускай скрипт. Что в логе?

У меня всё находит (на XP).



9:38:38 Страница 0
9:39:14 Страница 1
9:39:22 Страница 2
9:39:30 Страница 3
9:39:38 Страница 4
9:39:46 Страница 5
9:39:54 Страница 6
9:40:03 Страница 7
9:40:11 Страница 8
9:40:19 Страница 9
9:40:27 Ничего не найдено. Пройдено 10 страниц


а можно узнать скрип текста?
Title: Re: Поиск сайта по выдаче яндекса
Post by: Vint on August 21, 2014, 02:08:11 PM
Прочитай что ты процитировал и сделай. Ты выкладываешь не то.
Title: Re: Поиск сайта по выдаче яндекса
Post by: Enot on August 21, 2014, 04:31:22 PM
а все сделал спасибо

Title: Re: Поиск сайта по выдаче яндекса
Post by: Enot on August 21, 2014, 04:34:34 PM
у меня есть еще 1 вопрос.
сначала же программа меняет айпи потом запускает браузер
есть такой вопрос если айпи не рабочай то можно все заново цикл вернулся и поменял айпи адрес?
я нашел у вас тока он браузер закрывает http://crapware.aidf.org/forum/index.php?topic=1092.msg4798#msg4798
Title: Re: Поиск сайта по выдаче яндекса
Post by: Vint on August 21, 2014, 05:00:05 PM
Quote from: Enot on August 21, 2014, 04:34:34 PM
есть такой вопрос если айпи не рабочай то можно все заново цикл вернулся и поменял айпи адрес?
Как я долго ждал этого вопроса.
Конечно, нужно проверять и если странице не загрузилась идти на следующий цикл.
Title: Re: Поиск сайта по выдаче яндекса
Post by: Enot on August 21, 2014, 05:02:55 PM
Quote from: Vint on August 21, 2014, 05:00:05 PM
Quote from: Enot on August 21, 2014, 04:34:34 PM
есть такой вопрос если айпи не рабочай то можно все заново цикл вернулся и поменял айпи адрес?
Как я долго ждал этого вопроса.
Конечно, нужно проверять и если странице не загрузилась идти на следующий цикл.

а как сделать чтобы проверял?
Title: Re: Поиск сайта по выдаче яндекса
Post by: Enot on August 31, 2014, 09:06:26 AM
на мой вопрос не кто не ответит?
Title: Re: Поиск сайта по выдаче яндекса
Post by: Doda on January 21, 2016, 10:55:32 PM
Quote from: Enot on August 14, 2014, 01:18:57 PM
Спасибо Vint) огромное спасибо) как сайт раскручу буду должен))

Винт, он с тобой расквитался?)
Title: Re: Поиск сайта по выдаче яндекса
Post by: Vint on January 22, 2016, 02:54:04 PM
 :D ;D
Title: Re: Поиск сайта по выдаче яндекса
Post by: tema26mak on May 25, 2016, 12:54:24 AM
Здравствуйте подскажите а как сделать чтобы ключевая фраза могла состоять больше чем из двух слов?. У меня если подставить третье слово то оно скриптом не учитывается он воспринимает первые два. Хотелось бы через RNDFROM задать сразу несколько ключевых фраз из которых скрипт выбирал бы и дальше действовал . И второй вопрос можно ли этот скрипт использовать под другие браузеры хром, опера? Чтобы рэндомно запускался один из браузеров и с ним работал. Успешно получилось только с мозилой. Заранее спасибо!