Автокликер Clickermann :: Форум

Основной раздел => Общие вопросы => Topic started by: Jawson on September 17, 2015, 03:22:29 PM

Title: Кликер как макрос HELP
Post by: Jawson on September 17, 2015, 03:22:29 PM

Вопрос для знающих существует ли команда определяющая координаты под курсором для выполнения последующих команд, задержек, действий, нажатий желательно с примерами  :P

Title: Re: Кликер как макрос HELP
Post by: Oraven on September 17, 2015, 05:07:46 PM

Есть. Это системные переменные.

Code: (clickermann) [Select]

$_xmouse // возвращает координату мыши по X
$_ymouse // возвращает координату мыши по Y
Пример, запоминаем положение курсора, кликаем по найденному пикселу и возвращаем курсор на место.

Code: (clickermann) [Select]

GETSCREEN
IF_PIXEL_IN(0,0, $_xmax,$_ymax, 255)
   $sav_x = $_xmouse // сохраняем положение курсора
   $sav_y = $_ymouse
   LCLICK($_return1, $_return2) // кликаем
   MOVE($sav_x,$sav_y) // возвращаем курсор на место
   WAITMS(100)
END_IF

Title: Re: Кликер как макрос HELP
Post by: Jawson on September 17, 2015, 06:07:58 PM

Ну вот стряпал простой макрос, при наведении курсора на определенную координату горячей клавишей Alt+A активирую скрипт в котором надо: активировать клавишей 3 - магию и высадить её под курсор, потом выбрать клавишей Q тела и высадить 3 тела - 3раза лклм в это же место под курсор, потом выбрать магию клавишей 1 и активировать клавишей B, остановить скрипт, надеюсь описал понятно, у меня не выходит поправьте  пожалуйста что не так сделал :-\

Code: (clickermann) [Select]

// New Script
KEYPRESS(#3)  // Нажимаем цифру 3 Выбираем магию
WAITMS(500)   // Ждем 500мс
GETSCREEN
IF_PIXEL_IN(0,0, $_xmax,$_ymax, 255)
   $sav_x = $_xmouse // сохраняем положение курсора
   $sav_y = $_ymouse
   LCLICK($_return1, $_return2) // кликаем (высаживаем магию 3)
   MOVE($sav_x,$sav_y) // возвращаем курсор на место
   WAITMS(100)
END_IF
WAITMS(500)   // Ждем 500мс
KEYPRESS(#Q)  // Нажимаем букву Q Выбираем тело 1-3
WAITMS(500)   // Ждем 500мс
GETSCREEN
IF_PIXEL_IN(0,0, $_xmax,$_ymax, 255)
   $sav_x = $_xmouse // сохраняем положение курсора
   $sav_y = $_ymouse
   LCLICK($_return1, $_return2) // кликаем (высаживаем тело 1)
   WAITMS(100)
   LCLICK($_return1, $_return2) // кликаем (высаживаем тело 2)
   WAITMS(100)
   LCLICK($_return1, $_return2) // кликаем (высаживаем тело 3)
   WAITMS(100)
   MOVE($sav_x,$sav_y) // возвращаем курсор на место
   WAITMS(100)
END_IF
WAITMS(500)   // Ждем 500мс
KEYPRESS(#1)  // Нажимаем цифру 1 Выбираем магию
WAITMS(500)   // Ждем 500мс
KEYPRESS(#B)  // высаживаем магию (координаты заложены в "B")
halt // стоп 


Title: Re: Кликер как макрос HELP
Post by: Vint on September 17, 2015, 06:47:51 PM

Зачем ты каждый раз снимаешь новые координаты мыши? Весь смысл же не в этом.
Один раз сохрани координаты при старте в начале

Code: (clickermann) [Select]

   $sav_x = $_xmouse // сохраняем положение курсора
   $sav_y = $_ymouse
А потом "высаживать"

Code: (clickermann) [Select]

   LCLICK($sav_x, $sav_y) // кликаем (высаживаем магию 3)
Зачем там поиск красного пиксела?

Title: Re: Кликер как макрос HELP
Post by: Oraven on September 17, 2015, 06:57:45 PM

При чем тут поиск пиксела? Я тебе просто привел пример использования, а ты это вставил в скрипт, и на что ты надеялся?

Что это значит?

Quote

и высадить её под курсор

Каким образом? Кликами? Перетаскиванием?
Не плохо бы скриншот увидеть.

Title: Re: Кликер как макрос HELP
Post by: Jawson on September 18, 2015, 10:09:59 AM

Quote from: Vint on September 17, 2015, 06:47:51 PM

Зачем ты каждый раз снимаешь новые координаты мыши? Весь смысл же не в этом.
Один раз сохрани координаты при старте в начале

Code: (clickermann) [Select]

   $sav_x = $_xmouse // сохраняем положение курсора
   $sav_y = $_ymouse
А потом "высаживать"

Code: (clickermann) [Select]

   LCLICK($sav_x, $sav_y) // кликаем (высаживаем магию 3)
Зачем там поиск красного пиксела?

Quote from: Oraven on September 17, 2015, 06:57:45 PM

При чем тут поиск пиксела? Я тебе просто привел пример использования, а ты это вставил в скрипт, и на что ты надеялся?

Что это значит?

Quote

и высадить её под курсор

Каким образом? Кликами? Перетаскиванием?
Не плохо бы скриншот увидеть.

Ответ один потому что я нуб в этом вопросе, пока пользуюсь кликером поверхностно, клики по координатам через некоторые промежутки времени, в переменных, условиях и поисках пикселей и координат пока не бум бум, как бы для этого я тут и нахожусь чтобы набраться у вас великих гуру знаний и за это проявить  кармическую благодарность  ;)
P.S. По теме, да высадка идет кликом 1 раз ЛКМ
Общая картина: при наведении курсора на определенную координату (на скрине в кругах местах высадки) горячей клавишей Alt+A активирую скрипт в котором надо: активировать клавишей "3" - магию и высадить её под курсор кликом ЛКМ, потом выбрать клавишей "Q" тела и высадить 1-6 тела = 1-6 раз ЛКМ в это же место под курсор, потом выбрать магию клавишей "1" и активировать клавишей "B", остановить скрипт.

Title: Re: Кликер как макрос HELP
Post by: Oraven on September 18, 2015, 11:43:01 AM

Если требуется клик по текущему положению курсора то можно просто написать в координатах число с минусом.

Code: (clickermann) [Select]

LCLICK(-1,-1)
Вот что получилось

Code: (clickermann) [Select]

KEYPRESS(#3) // активируем магию
WAITMS(300)

LCLICK(-1,-1) // высаживаем её под курсор
WAITMS(300)

KEYPRESS(#Q) // выбираем тела
WAITMS(300)

FOR($a=0,$a<6) // повтор 6 раз (т.е. будет 6 кликов)
   LCLICK(-1,-1) // высаживаем
   WAITMS(100)
END_CYC

KEYPRESS(#1) // выбираем магию
WAITMS(300)
KEYPRESS(#B) // активируем

HALT // Стоп
Задержки в скрипте в миллисекундах
WAITMS(300) - задержка на 300 миллисекунд. В секунде 1000 мс

Title: Re: Кликер как макрос HELP
Post by: Jawson on September 18, 2015, 02:56:36 PM

Oraven Спасибо большое ваши советы и учения мне помогают  :)
Теперь я уперся в момент что каждый отдельно запущенный кликер оказывается не имеет своих собственных настроек, в том числе и по горячим клавишам, и это печально  :-\
Возможно ли привязать запуск отдельных кликеров к разным клавишам или возможно есть команда для скрипта которая будет активировать определенную часть скрипта при условии нажатия определённой клавиши, другими словами объединить два сценария в 1
К примеру:

Code: (clickermann) [Select]

//скрипт 1 при нажатии "A"
KEYPRESS(#3) // активируем магию
WAITMS(300)

LCLICK(-1,-1) // высаживаем её под курсор
WAITMS(300)

KEYPRESS(#Q) // выбираем тела
WAITMS(300)

FOR($a=0,$a<6) // повтор 6 раз (т.е. будет 6 кликов)
   LCLICK(-1,-1) // высаживаем
   WAITMS(100)
END_CYC

HALT // Стоп
и второй скрипт

Code: (clickermann) [Select]

//скрипт 2 при нажатии "B"
KEYPRESS(#E) // выбираем магию
WAITMS(300)
KEYPRESS(#R) // активируем ee
 
HALT // Стоп


Title: Re: Кликер как макрос HELP
Post by: Oraven on September 18, 2015, 03:21:32 PM

Что бы работали горячие клавиши у разных кликеров придется распихать по разным папкам, тогда у каждой копии будут свои настройки.

Но все решаемо через скрипт.
Запускаешь, скрипт крутится по кругу, если нажать A условие разрешит выполнить первый скрипт, если нажать B то второй. Все просто...

Code: (clickermann) [Select]

IF(ISKEYDOWN(#A)=1) //скрипт 1 при нажатии "A"
   WHILE(ISKEYDOWN(#A)=1)
      WAITMS(5)
   END_CYC
   
   KEYPRESS(#3) // активируем магию
   WAITMS(300)
   
   LCLICK(-1,-1) // высаживаем её под курсор
   WAITMS(300)
   
   KEYPRESS(#Q) // выбираем тела
   WAITMS(300)
   
   FOR($a=0,$a<6) // повтор 6 раз (т.е. будет 6 кликов)
      LCLICK(-1,-1) // высаживаем
      WAITMS(100)
   END_CYC
END_IF

IF(ISKEYDOWN(#B)=1) //скрипт 2 при нажатии "B"
   WHILE(ISKEYDOWN(#B)=1)
      WAITMS(5)
   END_CYC
   
   KEYPRESS(#E) // выбираем магию
   WAITMS(300)
   KEYPRESS(#R) // активируем ee
END_IF

WAITMS(20)

Title: Re: Кликер как макрос HELP
Post by: Jawson on September 19, 2015, 06:46:02 AM

Oraven "А ларчик просто открывался" Всего пару команд и теперь всё чудесно встало на свои места, буду теперь дальше вникать в тонкости, ещё раз спасибо большое, добра вам и удачи :-*