Автокликер Clickermann :: Форум

Основной раздел => Общие вопросы => Topic started by: Yoko on April 11, 2016, 02:27:31 AM

Title: Для игры.
Post by: Yoko on April 11, 2016, 02:27:31 AM

Доброго времени.
Совсем тяжело дается понимание работы данного кликера. Хочется максимально его использовать.
Итак...

В игре можно использовать клавиатуру и мышку, но через кликер работает только клавиатура через #ps2_keyboard
Функцианальность мышки в игре кликер никак не использует к сожалению.

Мне надо задать цикл использования:
Нажимать F1 каждые 20 минут
Нажимать F2 каждые 5 минут
Нажимать F3 каждые 3 минуты

Мне показали пример:

Code: [Select]

#ps2_keyboard
START:
$time = $_time_t0 + 1200
WHILE($time > $_time_t0)
KEYPRESS(#F1)
WAITMS(70)
END_CYC
WAITMS(70)
$time = $_time_t1 + 300
WHILE($time > $_time_t1)
KEYPRESS(#F2)
WAITMS(70)
END_CYC
WAITMS(70)
$time = $_time_t2 + 180
WHILE($time > $_time_t2)
KEYPRESS(#F3)
WAITMS(70)
END_CYC
WAITMS(70)
GOTO(START)
Но он к сожалению неверный, так как при запуске он нажимал F1 каждую секунду и мне заблокировали чат на 2 часа.
Подскажите, как правильно выставить время?

Title: Re: Для игры.
Post by: Oraven on April 11, 2016, 07:42:33 AM

Кто это тебе такое мог подсказать? Все не правильно.
$_time_t - это системная переменная возвращающая время Unix
$time - это обычная переменная с любым именем куда значение времени Unix будет записано. Для каждого условия имя этой переменной должно быть своим!
Далее в условии сравнивается IF($time1 < $_time_t) если $time1 меньше времени Unix то условие выполняется.
В конце условия мы записываем время Unix плюс 20 минут в переменную $time1 = $_time_t + 1200
Таким образом в следующие 20 минут это условие больше не будет срабатывать

Вот верный скрипт:
Кнопки F1 F2 F3 нажмутся сразу друг за другом, а потом через заданное для каждой кнопки время

Code: (clickermann) [Select]

#ps2_keyboard

IF($time1 < $_time_t)
   KEYPRESS(#F1)
   WAITMS(100)
   $time1 = $_time_t + 1200
END_IF

IF($time2 < $_time_t)
   KEYPRESS(#F2)
   WAITMS(100)
   $time2 = $_time_t + 300
END_IF

IF($time3 < $_time_t)
   KEYPRESS(#F3)
   WAITMS(100)
   $time3 = $_time_t + 180
END_IF

WAIT(1)
Вариант 2:

Кнопки F1 F2 F3 нажмутся через заданное для каждой кнопки время.
DEFINE объявляет переменную и записывает в нее значение но только 1 раз если этой переменной еще не существует.

Code: (clickermann) [Select]

#ps2_keyboard

DEFINE($time1, $_time_t + 1200)
IF($time1 < $_time_t)
   KEYPRESS(#F1)
   WAITMS(100)
   $time1 = $_time_t + 1200
END_IF

DEFINE($time2, $_time_t + 300)
IF($time2 < $_time_t)
   KEYPRESS(#F2)
   WAITMS(100)
   $time2 = $_time_t + 300
END_IF

DEFINE($time3, $_time_t + 180)
IF($time3 < $_time_t)
   KEYPRESS(#F3)
   WAITMS(100)
   $time3 = $_time_t + 180
END_IF

WAIT(1)

Title: Re: Для игры.
Post by: Yoko on April 11, 2016, 10:48:04 AM

то что надо, спасибо ) все работает.