Автокликер Clickermann :: Форум

Основной раздел => Общие вопросы => Topic started by: Ramzesia on June 20, 2017, 01:39:18 PM

Title: Вычислить время от-до
Post by: Ramzesia on June 20, 2017, 01:39:18 PM

Привет всем, прошу помочь вычислить время в милисекундах, которое пройдет от одной строчки до выбранной следующей.

Code: (clickermann) [Select]

WAITMS(RND(300,400))
LCLICK(RND(870,940),RND(370,444)) // Нужно вычислить время от этой строчи, то есть старт секундомера 
WAITMS(50)

$time1 = $_time_t + 30
WHILE($time1 > $_time_t)
   GETSCREEN (900,370, 910,390)
   COLORMODE (6,900,370, 910,390)
   IF_PICTURE_IN (900,370, 910,390, "texture\podse4ka.bmp", -1, 90) // Нужно вычислить время до этой строчки, после того как картинка нашлась записать в лог сколько прошло милисекунд
      $time1 = 0
      KEYPRESS(#c)
      WAITMS(300)
   ELSE
      WAITMS(50)
   END_IF
END_CYC

Title: Re: Вычислить время от-до
Post by: open_78 on June 20, 2017, 01:55:05 PM

И тебе привет.

Code: (clickermann) [Select]

WAITMS(RND(300,400))
LCLICK(RND(870,940),RND(370,444)) // Нужно вычислить время от этой строчи, то есть старт секундомера
$timestart = $_ms
WAITMS(50)

$time1 = $_time_t + 30
WHILE($time1 > $_time_t)
   GETSCREEN (900,370, 910,390)
   COLORMODE (6,900,370, 910,390)
   IF_PICTURE_IN (900,370, 910,390, "texture\podse4ka.bmp", -1, 90) // Нужно вычислить время до этой строчки, после того как картинка нашлась записать в лог сколько прошло миллисекунд
      PRINT ($_ms - $timestart)
      $time1 = 0
      KEYPRESS(#c)
      WAITMS(300)
   ELSE
      WAITMS(50)
   END_IF
END_CYC

Title: Re: Вычислить время от-до
Post by: Ramzesia on June 20, 2017, 09:03:12 PM

Спасибо большое! :)

Title: Re: Вычислить время от-до
Post by: Ramzesia on June 23, 2017, 12:15:25 AM

Привет, а можно что бы в секундах писалось? А то, слишком большое число получается.
Так пойдет?

Code: (clickermann) [Select]

$timestart = ROUND($_ms/1000, 0)
//Скрипт
PRINT ("Выполнено за - ", ROUND($_ms/1000, 0) - $timestart, " сек")

Title: Re: Вычислить время от-до
Post by: Vint on June 23, 2017, 07:54:42 AM

Пойдёт. Можно и в часы:минуты:сек.мс

http://crapware.aidf.org/forum/index.php?topic=1147.msg10807#msg10807
подключить файл logger.cms. Или выдрать

Code: (clickermann) [Select]

//==============================================================================
//===  Вывод времени выполнения ms в формате час:мин:сек,мс ====================
SUB(timeprint, $tt_print)
   // Пример вызова:
   // timeprint(12345)
   IF($tt_print > 999)
      $timesec = $tt_print/1000
      $hours = int($timesec/3600)
      $minuts = int(($timesec - ($hours*3600))/60)
      $sec = ($tt_print - ($hours*3600*1000) - ($minuts*60*1000)) / 1000
      LOGWRITE ($hours,":" ,$minuts ,":" ,$sec )
   END_IF
END_SUB

//==============================================================================
//===  Вывод времени выполнения  ===============================================
SUB(print_timeaction, $actionnamet, $tt_search)
   // Пример вызова:
   // $timer1 = $_ms
   // ...
   // print_timeaction("тест 1", $_ms - $timer1)
   LOGWRITE ("===============  время выполнения  ===============")
   LOGWRITE ("время выполнения ", $actionnamet, " : ", $tt_search, " мс")
   timeprint($tt_search)
   LOGWRITE (" ")
END_SUB

//==============================================================================
примеры использования в начале подпрограмм.