1
Использование / Gods and glory
« on: July 21, 2017, 11:06:48 AM »
Предлагаю скрипт фарма подзмелий игры Gods and glory
https://vk.com/godsandglory
https://vk.com/godsandglory
Code: (clickermann) [Select]
//скрипт выполняет майн подземелий в игре Gods and Glory
// подходит для сбора низкоуроуневых ресурсов для кузни
// останавливает сбор, когда войска начинают гибнуть
// или когда полоска очков подземелья заполняется почти до максимума
// запускать в ноксе, пришвартованном к левому верхнему углу экрана
#name "Слава шахтёрам"
//процедура клика с рандомным отклонением от точки клика на количество точек от 0 до $rc по обеим осям
sub (clkr, $xc,$yc,$rc)
$nx=$xc+rnd(0-$rc,$rc)
$ny=$yc+rnd(0-$rc,$rc)
// print(" x",$xc," y",$yc," nx",$nx, " ny",$ny)
$getx=$_xmouse
$gety=$_ymouse
MOVE($nx,$ny)
LDOWN($nx,$ny)
waitms(80+rnd(0,60))
LUP($nx,$ny)
MOVE($getx,$gety)
end_sub
//процедура рандомного ожидания таймер + 1-10%
sub(waitrnd, $t)
WAIT($t+$t*(1/rnd(1,10)))
end_sub
//main part основная часть
GETSCREEN
COLORMODE(6)
//screenshot
WHILE(pxl(226,185)=4144959) //проверка по заполненности полоски очков,этот цикл можно поменять, если требуется другое условие для окончания фарма
print("Можно в бой, очки есть куда собирать",pxl(315,500))
//рандомно бьем один из отрядов в списке, можно выбирать только один из 2-х вариантов
// вариант 1: бьем только нижние 4 отряда в подземелье, например, для защиты от дыхания дракона
clkr(325,341+76*rnd(0,3),5)
//вариант 2: бьем все 5 отрядов, имеет смысл использовать при отключенной проверке на войска, но при уверенности, что остаток войск вытянет бои со всеми отрядами. иначе скрипт будет часто останавливаться т.к. войска будут дохнуть. ГГ маг вполне норм может фармить
// clkr(325,263+76*rnd(0,4),5)
waitrnd(1)
//тут проверка на наличие войск в армии по цвету полоски,если войска начинают дохнуть и не пополняются, то хальт, можно отключить и биться, к пример, только основным героем
GETSCREEN
COLORMODE(6)
IF(pxl(210,230)=4144959)
print("войска закончились! блеа!!!")
halt
END_IF
//начать бой на выборе войск
clkr(281,589,5)
waitrnd(2)
//начать бой на поле
clkr(199,612,5)
//дальше ждем конца, проверяем наличие кнопки
GETSCREEN
COLORMODE(6)
print("бой идет",pxl(315,500))
WHILE(pxl(315,500)!8355711)
waitrnd(1)
print("бой идет",pxl(315,500))
GETSCREEN
COLORMODE(6)
end_cyc
//раздача призов
//выбираем первый приз
$pp=rnd(0,4)
clkr(55+66*$pp,444,7)
waitrnd(0.2)
clkr(55+66*$pp,444,7)
waitrnd(0.6)
// а здесь выбираем второй приз. можно отключить всю эту конструкцию, если можно брать только один приз
$vp=$pp
WHILE($vp=$pp)
$vp=rnd(0,4)
waitrnd(0.1)
end_cyc
clkr(55+66*$vp,444,7)
waitrnd(0.2)
clkr(55+66*$vp,444,7)
waitrnd(1.5)
//после сбора призов можно выходить
clkr(280,496,10)
waitrnd(2)
GETSCREEN
COLORMODE(6)
end_cyc
//конец цикла, если очки набрались
print("мы почти у цели, дальше пили сам")
halt