Messages

3901

Предложения / Re: Анализ текста в окне

« on: December 11, 2012, 10:44:14 AM »

AGClient 

Как вариант... Только производительность нужна хотя бы 10 китайцекартинок в секунду.

3902

Общие вопросы / Re: Clickermann v4.7 SE+ Новые возможности. Особенности.

« on: December 11, 2012, 09:16:01 AM »

Вы что ночами не спите?
Да, да вот точно... Даже просто автоматически запускать кликер со скриптом где нужно было  поKEYSTRINGить на английском обламывался. Только так запустил-переключил-GO.
(В целевом окне справлялся Punto switcher? только проходилось иногда добавлять пробел/backspace если слово одно или строка непрерывная)
to ЦИТРИН. Не воспринимай всё буквально. Тебе ничего добавлять не нужно. Возможно пока.

3903

Общие вопросы / Re: Оконный режим...

« on: December 10, 2012, 09:43:50 PM »

А по заголовку окно поймать не?
Вот этой штукой легко http://clickermann.tk/forum/index.php?topic=42.msg572#msg572

3904

Общие вопросы / Re: Clickermann v4.7 SE+ Новые возможности. Особенности.

« on: December 10, 2012, 09:18:36 PM »

Я в оконном режиме не работал пока.
Для чего это нужно вообще?

Да дело не в оконном режиме. KEYSTRING и TOCLIP ("str") зависим не только от языка целевого окна, а и от языка окна кликермэна. Иначе выводились пробелы с точками. Теперь эта проблема решена. Ура Автору! Ура товарищи!

3905

Общие вопросы / Re: Clickermann v4.7 SE+ Новые возможности. Особенности.

« on: December 10, 2012, 05:10:46 PM »

Всё. Теперь во все скрипты, как минимум, вначале повставляю строчку

Code: (clickermann) [Select]

SETKBLAYOUT((WNDFIND("Clickermann - ")), 1033)А то задолбался.

3906

Общие вопросы / Re: Clickermann v4.7 SE+ Новые возможности. Особенности.

« on: December 10, 2012, 04:40:19 PM »

Да ладно а уменя все работает. Попробуй на справке от кликера

Всё попробовал, ничего не пашет...
Что интересно запускаю v4.7.001 полное наименование - находит, SE тот же микроскрипт - нет.

Сори, ввёл в заблуждение. Перезагрузил комп и стало ловить
Шайтан. А я уже панику поднял  Как так? кто кликера душил?

3907

Общие вопросы / Re: Clickermann v4.7 SE+ Новые возможности. Особенности.

« on: December 10, 2012, 03:38:08 PM »

В SE указано исправление работа ф-ции WNDFIND
Я обрадовался. Раньше находило если заголовок указывался только полностью.
Попробовал в новой версии - вообще перестало работать. Хоть неполная, хоть полная.
Хэлп!!!

3908

Архив / Re: Объединение строковых и численных переменных

« on: December 10, 2012, 02:49:05 PM »

Ты проще введи ещё одну переменную вместо своих токлипов, чего экономить, особенно теперь
И хоть обнуляй её, хоть зануляй...
Всё равно ведь INT добавлять нужно будет.

3909

Архив / Re: Объединение строковых и численных переменных

« on: December 10, 2012, 01:51:44 PM »

Аналогичная ошибка возникает, если загнать  в буфер  переменную, а потом её  извлечь.( синяя подсветка)
 Скрипт останавливается и на экране красным выводится строка ( тут подсвечена красным) .

Не получается повторить.
Вот всё нормально:

Code: (clickermann) [Select]

TOCLIP (3)
$_b = FROMCLIP ()
IF (($b-1) < 5)   
   HINTPOPUP("Всё нормально")
END_IF
А в твоём примере не хватает одного END_IF

P.S.
А, да... не нормально. Ну ничего.

Code: (clickermann) [Select]

TOCLIP ("9")
$_b = FROMCLIP ()
IF (($b-1) < 5)
   $f=$b-1
   LOGWRITE ($f)   
END_IF
А в твоём примере вообще TOCLIP нафиг не нужен, ты буфер используешь как переменную.

3910

Общие вопросы / Re: Clickermann v4.7 SE+ Новые возможности. Особенности.

« on: December 10, 2012, 10:21:35 AM »

Да, за GETKBLAYOUT и SETKBLAYOUT Джони отдельное спасибо. Правда пока не пробовал.
О версии SE хоть бы маякнул кто, а то на основной сайт повода небыло заходить.
Я думал данные изменения (в SE) ещё долго не выпустят... Была надежда на "долгую" перспективу.

Я туплю. Чем отличаются TFREAD от STRREADLN

3911

Архив / Re: Ошибка PRINT c $ знаком

« on: December 08, 2012, 04:46:14 PM »

пользуйтесь рублями.

Ты прям как наше правительство 

3912

Предложения / Re: Анализ текста в окне

« on: December 08, 2012, 01:07:44 PM »

Среднее арифметическое ты сейчас и там можешь посчитать, что мешает?
Поиск текста обсуждался в теме поиск текста в браузере. Да, хорошо бы делать это быстро и просто.
Только сдается мне что тебе это не подойдет. Потому что в большинстве таких игр текст на экране это не текст, а картинка с надписью. Нет, внутри программы это чаще именно текст, но тебе это не поможет. Попробуй выделить свою надпись и скопировать. Не выделится.
А кликкер  совсем не "фаинридер".

3913

Прочее / Re: Avast взял и резко заругался на форум

« on: December 08, 2012, 12:38:03 PM »

Всё так сразу и сделал. И теперь каждый раз...
Надеюсь никто не предложит, как выход, написать скрипт для кликкермена для входа на форум. :-)

3914

Использование / Re: Ребят очень надо помогите написать сценарий

« on: December 07, 2012, 10:57:19 PM »

Вот как дома работает:
http://youtu.be/XXXXXXXXXX
Домотал только после 2:10 примерно.

3915

Использование / Re: Ребят очень надо помогите написать сценарий

« on: December 07, 2012, 03:16:20 PM »

Ну вот такой...
Проверяй. Если что-то не работает пиши.
ЦУ:
Версия Clickermann  -  v4.7.001
Окно с карточками должно быть загружено.
Перематывать не нужно, само перемотает.
Если страница первая перемотает чуть быстрее. (параметр $speed=20 можно менять, в "сезон" лучше выставить больше)
Идём вперёд до "часа", потом проверяем назад (58-59 минуты), после проверяем только 59-ю.
Балансируем туда-сюда.

Code: (clickermann) [Select]

#name "FIFA"
// Author: Vint
// Version: 2.0 (07.12.2012)

//--------------------------------
$speed=20 // количество страниц пропускаемых, от начала, быстро без проверки
//--------------------------------

//--------------------------------
$forward=1 // o-нет перемотки, 1-перемотка вперёд
//--------------------------------


WAIT(1)

//====  Находим Fifa
MOVE($_xmax, $_ymax)  //паркуемся
GETSCREEN
COLORMODE(5)
IF_PICTURE_IN (0,0, $_xmax, $_ymax, "textures\home.bmp")
   LCLICK($_return1,$_return2+70)
   WAITMS(100)
   $vX=$_return1-16
   $vY=$_return2+51
   LOGWRITE("Fifa found")
   LOGWRITE("$vX = ", $vX, "  $vY = ", $vY)
   WAITMS(200)
ELSE
   LOGWRITE("Fifa not found")
   HINTPOPUP("Fifa not found")
   HALT
END_IF

//====  Инициализация
$first=1 // 1-перый проход, 0- не первый
$napr=2 // куда идём 1-влево, 2-вправо
$sdelano=0 // счётчик купленных карточек
$park_x=$vX+640 // парковка
$park_y=$vY+220
$page_Lx=$vX+405 // стрелка по страницам  влево
$page_Ly=$vY+220
$page_Rx=$vX+558 // стрелка по страницам  вправо
$page_Ry=$vY+220
$stavka_1x=$vX+540 //  поле stavka
$stavka_1y=$vY+122
$stavka_2x=$vX+600
$stavka_2y=$vY+140
$nostavka_1x=$vX+440 //  поле no_stavka
$nostavka_1y=$vY+90
$nostavka_2x=$vX+470
$nostavka_2y=$vY+102
$gebot_1x=$vX+390 //  поле gebot
$gebot_1y=$vY+120
$gebot_2x=$vX+435
$gebot_2y=$vY+142
$startmany_1x=$vX+460 //  поле startmany
$startmany_1y=$vY+50
$startmany_2x=$vX+480
$startmany_2y=$vY+70
$basik_1x=$vX+3 //  поле карточек
$basik_1y=$vY+248
$basik_2x=$vX+840
$basik_2y=$vY+266
$lx=$vX+40 //  левая карточка
$ly=$vY+275
$l_1x=$vX+140 //  поле левой карточки
$l_1y=$vY+140
$l_2x=$vX+222 //250 старое значение
$l_2y=$vY+158
$rx=$vX+820 //  правая карточка
$ry=$vY+275
$r_1x=$vX+850 //  поле правой карточки
$r_1y=$vY+140
$r_2x=$vX+920
$r_2y=$vY+158

//====

IF($forward=0)
   //GOTO(poisk)    //для отладки
   GOTO(start)
END_IF

GETSCREEN        // если 1-я стр. мотаем на ~30 страниц без проверки
IF_PICTURE_IN ($vX+420,$vY+210,$vX+510,$vY+228, "textures\seite1von.bmp")
   LOGWRITE("1 page, forward ~30")
   $i=0
   FOR($i, $i < $speed)     // мотаем вправо на N страниц
      LCLICK($page_Rx,$page_Ry)
      WAITMS(100)
      GOSUB(zagruzka)
   END_CYC
END_IF

$pic = 1          // перелистывание вправо по 5 страниц
WHILE($pic = 1)
   MOVE($lx, $ly)  //  левая карточка
   WAITMS(150)
   
   $fon = 1
   WHILE($fon = 1)
      GETSCREEN
      IF (PXL($lx+60, $ly-137)=6643283)
         $fon = 0
      END_IF
      WAITMS(100)
   END_CYC
   
   GETSCREEN
   IF_PICTURE_IN ($l_1x,$l_1y,$l_2x,$l_2y, "textures\stunden.bmp")
      $pic = 0
      LCLICK($page_Lx,$page_Ly)   // на 1 страницу назад
      WAITMS(100)
      GOSUB(zagruzka)
   ELSE
      $i=0
      FOR($i, $i < 5)    // 5 раз вправо
         LCLICK($page_Rx,$page_Ry)
         WAITMS(100)
         GOSUB(zagruzka)
      END_CYC
      $pic = 1
   END_IF
   //LOGWRITE("$pic ",$pic)
END_CYC



//====
start:

// проверка stunden слева
MOVE($lx, $ly)  //  левая карточка
WAITMS(150)

$fon = 1
WHILE($fon = 1)
   GETSCREEN
   IF (PXL($lx+60, $ly-137)=6643283)
      $fon = 0
   END_IF
   WAITMS(100)
END_CYC

GETSCREEN
IF_PICTURE_IN ($l_1x,$l_1y,$l_2x,$l_2y, "textures\stunden.bmp")
   LCLICK($page_Lx,$page_Ly)
   WAITMS(200)
   GOSUB(zagruzka)
   $napr=1
   GOTO(start)
END_IF

// проверка меньше 58-59 справа
MOVE($rx, $ry)  //  правая карточка
WAITMS(150)

$fon = 1
WHILE($fon = 1)
   GETSCREEN
   IF (PXL($rx+60, $ry-137)=6643283)
      $fon = 0
   END_IF
   WAITMS(100)
END_CYC
WAITMS(100)

$nichego=0
$poisk=0
GETSCREEN
IF_PICTURE_IN ($r_1x,$r_1y,$r_2x,$r_2y, "textures\stunden.bmp")
   $poisk=1
   $napr=1
   INC($nichego)
END_IF

IF($first=1)
   IF_PICTURE_IN ($r_1x,$r_1y,$r_2x,$r_2y, "textures\58_1sm.bmp")
      $poisk=1
      $napr=2
      INC($nichego)
   END_IF
   
   IF_PICTURE_IN ($r_1x,$r_1y,$r_2x,$r_2y, "textures\58_2sm.bmp")
      $poisk=1
      INC($nichego)
   END_IF
END_IF

IF_PICTURE_IN ($r_1x,$r_1y,$r_2x,$r_2y, "textures\59_1sm.bmp")
   $poisk=1
   INC($nichego)
END_IF

IF_PICTURE_IN ($r_1x,$r_1y,$r_2x,$r_2y, "textures\59_2sm.bmp")
   $poisk=1
   INC($nichego)
END_IF

IF(($nichego=0) & ($first=1)) // проверка первого прохода, оптимизация
   $first=0
END_IF

IF($poisk=0)
   LCLICK($page_Rx,$page_Ry)
   WAITMS(200)
   GOSUB(zagruzka)
   $napr=2
   GOTO(start)
END_IF

poisk:
$basik_temp=$basik_1x

WHILE($basik_temp<$basik_2x)
   MOVE($lx, $ly)
   WAITMS(100)
   
   $fon = 1
   WHILE($fon = 1)
      GETSCREEN
      IF (PXL($lx+60, $ly-137)=6643283)
         $fon = 0
      END_IF
      WAITMS(100)
   END_CYC
   
   MOVE($park_x, $park_y)  //паркуемся
   WAITMS(300)
   
   GETSCREEN
   //LOGWRITE("ищу 75")
   IF_PICTURE_IN($basik_temp,$basik_1y,$basik_2x,$basik_2y, "textures\75_1sm.bmp")
      $basik_temp=$_return1+60
      LOGWRITE("nashli 75")
      GOSUB(nashli_75)
   ELSE
      IF_PICTURE_IN($basik_temp,$basik_1y,$basik_2x,$basik_2y, "textures\75_2sm.bmp")
         $basik_temp=$_return1+60
         LOGWRITE("nashli 75")
         GOSUB(nashli_75)
      ELSE
         $basik_temp=$basik_2x+1
         LOGWRITE("нет 75")
         //HINTPOPUP("нет 75")
      END_IF
   END_IF
END_CYC

//HALT

IF($napr=1)
   LCLICK($page_Lx,$page_Ly)
   WAITMS(300)
ELSE
   LCLICK($page_Rx,$page_Ry)
   WAITMS(300)
END_IF
GOSUB(zagruzka)

//LOGWRITE("На старт")
GOTO(start)
HALT


//==============================================================================
SUB(nashli_75) //======== nashli_75  ===========================================
   LCLICK($_return1,$_return2)
   WAITMS(300)
   $picgdem= "textures\start_many.bmp"
   $picgd_1x=$startmany_1x
   $picgd_1y=$startmany_1y
   $picgd_2x=$startmany_2x
   $picgd_2y=$startmany_2y
   GOSUB(gdem_kartinku)
   
   GETSCREEN
   IF_PICTURE_IN ($vX+350,$vY+19,$vX+380,$vY+35, "textures\stunden_kart.bmp")
      $basik_temp=$basik_temp+62
      $napr=1
      LOGWRITE("проверку stunden не прошла, время stunden")
      GOTO(end_nashli)
   END_IF
   WAITMS(500)
   IF_PICTURE_IN ($nostavka_1x,$nostavka_1y,$nostavka_2x,$nostavka_2y, "textures\no_stavka.bmp")
      IF_PICTURE_IN ($gebot_1x,$gebot_1y,$gebot_2x,$gebot_2y, "textures\gebot_150.bmp")
         LCLICK($vX+468,$vY+132)
         WAITMS(200)
         LCLICK($vX+468,$vY+132)
         WAITMS(200)
         GOSUB(stavka)
         GOTO(end_nashli)
      END_IF
     
      IF_PICTURE_IN ($gebot_1x,$gebot_1y,$gebot_2x,$gebot_2y, "textures\gebot_200.bmp")
         LCLICK($vX+468,$vY+132)
         WAITMS(200)
         GOSUB(stavka)
         GOTO(end_nashli)
      END_IF
     
      IF_PICTURE_IN ($gebot_1x,$gebot_1y,$gebot_2x,$gebot_2y, "textures\gebot_250.bmp")
         WAITMS(200)
         GOSUB(stavka)
      END_IF
   ELSE
      LOGWRITE("уже есть ставка")
   END_IF
end_nashli:
GOSUB(zagruzka)
END_SUB


//==============================================================================
SUB(stavka) //=========== stavka  ==============================================

WAITMS(200)
GETSCREEN
IF_PICTURE_IN ($gebot_1x,$gebot_1y,$gebot_2x,$gebot_2y, "textures\gebot_250.bmp")
   IF_PICTURE_IN ($stavka_1x,$stavka_1y,$stavka_2x,$stavka_2y, "textures\stavka.bmp")
      LOGWRITE("НАШЁЛ!!! СТАВЛЮ!!!")
      //HINTPOPUP("НАШЁЛ!!! СТАВЛЮ!!!") //заглушка для отладки
      //HALT                          //заглушка для отладки
      LCLICK($_return1,$_return2)
      WAITMS(1500) // задержка на проверку успел-нет
      GOSUB(oblom)
   END_IF
   WAITMS(300)
   GOSUB(zagruzka)
END_IF
END_SUB


//==============================================================================
SUB(oblom) //=========== опоздал, хе-хе  =======================================

GETSCREEN
IF_PICTURE_IN (0,0,$_xmax,$_ymax, "textures\ok.bmp")
   LCLICK($_return1,$_return2)
   LOGWRITE("Опоздали. Hi-hi.")
ELSE
   INC($sdelano)
   LOGWRITE("Подтвердил ставку")
   LOGWRITE("Куплено карточек всего: ", $sdelano)
   WAITMS(200)
END_IF

END_SUB


//==============================================================================
SUB(zagruzka) //=========== zagruzka  ==========================================

MOVE($park_x, $park_y)  //паркуемся
WAITMS(150)

$gknb_sch=0
$pic = 1
WHILE($pic = 1)
   INC ($gknb_sch)
   IF($gknb_sch = 30)
      LOGWRITE("Не дождался загрузки")
   END_IF
   
   GETSCREEN
   IF ((PXL($vX+182,$vY+11)=15658217) & (PXL($vX+170,$vY+20)=15657960))
      $pic = 0
   END_IF
   WAITMS(100)
END_CYC
END_SUB


//==============================================================================
SUB(gdem_kartinku) //======== gdem_kartinku  ===================================

MOVE($park_x, $park_y)  //паркуемся
WAITMS(300)

$gknb_sch=0
$pic = 1
WHILE($pic = 1)
   INC ($gknb_sch)
   IF($gknb_sch = 30)
      LOGWRITE("Не дождался картинки")
   END_IF
   
   GETSCREEN
   IF_PICTURE_IN ($picgd_1x,$picgd_1y, $picgd_2x, $picgd_2y, $picgdem)
      $pic = 0
   END_IF
   WAITMS(100)
END_CYC
END_SUB


//==============================================================================

За оформление,... $vX,... $vY,... и др. спасибо Oraven.