Как реализовать поиск нескольких картинок?

[kin2005]

Как реализовать работу скрипта с несколькими картинками? Допустим имеем картинки 1.bmp, 2.bmp,.... 5.bmp всего 5 картинок, нужно чтобы скрипт останавливался при нахождении любой из картинок в 1-3 экземплярах либо их комбинаций.

С одной работает прекрасно:

Code: [Select]

$a=0
$p=105

retry:
$a=$a+1
print("try: ",$a)
waitms(100)

LCLICK(497,647)

wait(3)

getscreen
colormode(8)
$var=0
$m=0

scanpicture($var, 328,378, 519,466, "1.bmp", -1,98)

while (arrsize($var) > 0)
   $y = arrpop($var)
   $x = arrpop($var)

   
   $m=$m+1
   
end_cyc

$m=$m-1
print("result: "$m)

if ($m < 1)
   goto(retry)
else
   halt
end_if



[Oraven]

Code: (clickermann) [Select]

LCLICK(497,647)
wait(3)

GETSCREEN
COLORMODE(8)
SCANPICTURE($arr1, 328,378, 519,466,"1.bmp",-1,98)
SCANPICTURE($arr2, 328,378, 519,466,"2.bmp",-1,98)
SCANPICTURE($arr3, 328,378, 519,466,"3.bmp",-1,98)
SCANPICTURE($arr4, 328,378, 519,466,"4.bmp",-1,98)
SCANPICTURE($arr5, 328,378, 519,466,"5.bmp",-1,98)

$count = 0 // обнуляем счетчик

$c = ARRSIZE($arr1)/2 // определяем сколько найдено картинок
IF(($c > 0)&($c < 4)) // условие, если больше нуля и меньше четырех. То есть 1-3
   INC($count,$c) // прибавляем количество найденных картинок к нашему счетчику
END_IF

$c = ARRSIZE($arr2)/2 // так же для остальных картинок
IF(($c > 0)&($c < 4))
   INC($count,$c)
END_IF

$c = ARRSIZE($arr3)/2
IF(($c > 0)&($c < 4))
   INC($count,$c)
END_IF

$c = ARRSIZE($arr4)/2
IF(($c > 0)&($c < 4))
   INC($count,$c)
END_IF

$c = ARRSIZE($arr5)/2
IF(($c > 0)&($c < 4))
   INC($count,$c)
END_IF

LOGWRITE ("Всего найдено: ", $count)

IF($count > 0) // в итоге если счетчик стал больше нуля то стоп
   HALT
END_IF

UNDEFINE($arr1) // обнуляем массивы
UNDEFINE($arr2)
UNDEFINE($arr3)
UNDEFINE($arr4)
UNDEFINE($arr5)

[kin2005]

Блин как элементарно, спасибо, что расписали где и что, все работает!!! Благодарю! Куда спасибо положить? )
и кстати будет ли такое работать?

Code: [Select]

$c = ARRSIZE($arr1)+ARRSIZE($arr2)
IF(($c > 1)&($c < 4))
   INC($count,$c)
END_IFили правильнее

Code: [Select]

$c = ARRSIZE($arr1)/2+ARRSIZE($arr2)/2
IF(($c > 1)&($c < 4))
   INC($count,$c)
END_IF