« previous next »
Pages: [1]

Author Topic: Помогите написать скрипт с циклом в цикле с IF_PIXEL_IN  (Read 2730 times)

0 Members and 3 Guests are viewing this topic.

vizaritm

  • Зашел в гости
  • *
  • Posts: 11
    • View Profile
Помогите написать скрипт с циклом в цикле с IF_PIXEL_IN
« on: January 19, 2018, 12:08:18 AM »
Действие мышью

//sub(qwer)
Проверям желтый пиксель
  если есть: действие мышью
             WAIT(10)
             проверяем синий пиксель (можно интерпретировать как, пока есть  синий ничего не делаем)
             если есть: ожидание
                        возврат к проверке синего пикселя
             если нет:  возврат к проверке желтого пикселя
  Если нету: конец кольца

Проверка картинки 1
  если есть: клик мышью по картинке 1
Проверка картинки 2
  если есть: ничего не делаем
  Если нет: ждем
            возврат к проверки картинки 2
end_sub
qwer()

//
Манипуляции мышью
Проверка картинки 3
  если есть: возврат к началу скрипта
Манипуляции с мышкой
qwer()
возврат к началу скрипта
Logged

dramster

  • Герой форума
  • *****
  • Posts: 1134
    • View Profile
Re: Помогите написать скрипт с циклом в цикле с IF_PIXEL_IN
« Reply #1 on: January 19, 2018, 12:51:30 AM »
наверно так?
Code: (clickermann) [Select]
sub(qwer)
   $check_yellow = 0
   WHILE($check_yellow = 0) // пока есть  желтый
     
      GETSCREEN
      IF_PIXEL_IN(0,0, $_xmax,$_ymax, 62207) //Проверям желтый пиксель
         LCLICK($_return1, $_return2) //если есть: действие мышью
         WAIT(10)
         
         $check_blue = 0
         WHILE($check_blue = 0) // пока есть  синий ничего не делаем
            GETSCREEN
            IF_PIXEL_IN(0,0, $_xmax,$_ymax, 13387839)
               WAITMS(100)
            ELSE
               $check_blue = 1  //если нет:  возврат к проверке желтого пикселя
            END_IF
         END_CYC
         
      else
         $check_yellow = 1 //Если нету: конец кольца
      END_IF
     
   END_CYC
   
   GETSCREEN
   IF_PICTURE_IN (0,0, $_xmax,$_ymax, "картинка_1.bmp", -1, 100) //Проверка картинки 1
      LCLICK($_return1, $_return2)  //если есть: клик мышью по картинке 1
      WAITMS(100)
   END_IF
   
   $check_pic_2 = 0
   WHILE($check_pic_2 = 0)
      GETSCREEN
      IF_PICTURE_IN (0,0, $_xmax,$_ymax, "картинка_2.bmp", -1, 100)
         $check_pic_2 = 1   //  если есть: ничего не делаем
         WAITMS(100)
      ELSE
         WAITMS(100)//Если нет: ждем
         // возврат к проверки картинки 2
      END_IF
   END_CYC
   
end_sub



LCLICK(10,10) //Манипуляции мышью

GETSCREEN
IF_PICTURE_IN (0,0, $_xmax,$_ymax, "картинка_3.bmp", -1, 100) //Проверка картинки 3
   waitms(100)
   //если есть: возврат к началу скрипта
else
   //Манипуляции с мышкой  (если нету картинки 3)
   LCLICK(10,10)
   
   qwer()
END_IF
//возврат к началу скрипта
Logged

vizaritm

  • Зашел в гости
  • *
  • Posts: 11
    • View Profile
Re: Помогите написать скрипт с циклом в цикле с IF_PIXEL_IN
« Reply #2 on: January 19, 2018, 06:12:12 AM »
ООооо спс человече, шаблон есть, сегодня, завтра буду тестировать, подставлять клики мыши. Уже выявлена проблема с цветопередачей, т.к. она слегка меняется, вроде получилось определить цвета, подставить COLORMODE. 
Это кстати бот для Eve online для набития стендинга(отношения фракции) на курьерских миссиях
В подпрорамме полет в пространстве, картинки 1 - вариация окончания прокладки маршрута, с мисиией или без(вход в док в окне агентва), картинка 2 проверка на готовность стыковки со станцией,, потом клики мыши со здачей задания, картинка 3 вариация если агент на тойже станции что и ты, или другой. Тут или выполняем подподграму с полетом, или начинаем с начало скрипт по принятию миссии.
Что из этого выйдет отпишу.

Logged

vizaritm

  • Зашел в гости
  • *
  • Posts: 11
    • View Profile
Re: Помогите написать скрипт с циклом в цикле с IF_PIXEL_IN
« Reply #3 on: January 20, 2018, 01:03:45 PM »
В общем то что получилось, рабочий бот для Eve online, курьерские миссии
П.С. Окно агенства и окно склада должны быть открыты.
Code: [Select]
//=============================================
sub(qwer)
   LCLICK(944,17)  // Клик на окно
   WAIT(3)
   MOVE(1551,264)
   WAIT(3)
   LCLICK(1551,264)  // клик на чтроку оверлея
   WAIT(3)
   
   skip1:
   $check_yellow = 0
   WHILE($check_yellow = 0) // пока есть  желтый
      GETSCREEN
      COLORMODE(7, 655,46, 1717,1011)
      LOGWRITE ("Проверяем желтый варп")
      IF_PIXEL_IN(1511,257, 1530,270, 8388607, 8388350, 8388093) //Проверям желтый пиксель
         LOGWRITE ("Желтый варп найден")
         MOVE(1574,134)    //если есть: действие мышью
         WAIT(4)
         LCLICK(1574,134)
         WAIT(15)
         
         $check_blue = 0
         WHILE($check_blue = 0) // пока есть  синий ничего не делаем
            GETSCREEN
            COLORMODE(7, 890,970, 910,990)
            LOGWRITE ("Проверка синего")
            $Найденый цвет = PXL(893,984)
            LOGWRITE ("Найденый цвет:", $Найденый цвет)
            IF_PIXEL_IN(893,984, 8355711)
               LOGWRITE ("Ожидание")
               WAIT(6)
            ELSE
               $check_blue = 1  //если нет:  возврат к проверке желтого пикселя
               LOGWRITE ("Синий не найден")
               WAIT(4)
            END_IF
         END_CYC
         
      else
         $check_yellow = 1 //Если нету: конец кольца
         LOGWRITE ("Желтый варп не  найден")
      END_IF
   END_CYC
   
   
   GETSCREEN
   COLORMODE(7, 1333,409 , 1482,460)
   LOGWRITE ("Проверка входа в док")
   IF_PICTURE_IN (1333,409 , 1482,460, "Enter dock 7.bmp", -1, 90)
      MOVE($_return1, $_return2)
      WAIT(2)
      LCLICK($_return1, $_return2)
      LOGWRITE ("Вход в док")
      WAIT(15)
   ELSE
      LOGWRITE ("Вход в док не найден")
   END_IF
   
   $check_pic_2 = 0
   WHILE($check_pic_2 = 0)
      GETSCREEN
      COLORMODE(8, 1623,167 , 1708,215)
      LOGWRITE ("Проверка окончания стыковки")
      IF_PICTURE_IN (1623,167 , 1708,215, "Exit 8.bmp", -1, 80)
         $check_pic_2 = 1   //  если есть: ничего не делаем
         WAITMS(100)
      ELSE
         WAIT(15)  //Если нет: ждем
         LOGWRITE ("Стыковка не окончена")
         goto(skip1)
         
      END_IF
   END_CYC
   LOGWRITE ("Конец стыковки")
end_sub
//=============================================

LOGWRITE ("Начало скрипта")
LCLICK(867,22)  // 15128779

MOVE(754,122)
WAIT(1)
LCLICK(754,122)  // 3156759

GETSCREEN
COLORMODE(8, 45,45, 1700,1000)
LOGWRITE ("Проверка присутствия агента на стации")
IF_PICTURE_IN (1333,409 , 1482,460, "Talk 8.bmp", -1, 98)
   LOGWRITE ("Агент на базе - начать разговор")
   MOVE($_return1, $_return2)
   WAIT(1)
   LCLICK($_return1, $_return2)
   WAIT(1)
   
   GETSCREEN
   COLORMODE(8, 72,43, 1766,1018)
   LOGWRITE ("Проверка запросить задание")
   IF_PICTURE_IN (72,43, 1766,1018, "Requiest 8.bmp", -1, 100)
      LOGWRITE ("Удачно")
      WAITMS(100)
      MOVE($_return1, $_return2)
      WAIT(2)
      LCLICK($_return1, $_return2)
      WAIT(3)
   else
      LOGWRITE (Не найдено")
   END_IF
   
   GETSCREEN
   COLORMODE(8, 72,43, 1766,1018)
   LOGWRITE ("Проверка просмотрара заданий")
   IF_PICTURE_IN (72,43, 1766,1018, "Look mission 8.bmp", -1, 100)
      LOGWRITE ("Удачно")
      WAITMS(100)
      MOVE($_return1, $_return2)
      WAIT(2)
      LCLICK($_return1, $_return2)
      WAIT(3)
   else
      LOGWRITE ("Не найдено")
   END_IF
   
   
   GETSCREEN
   COLORMODE(8, 14,43, 1766,1018)
   LOGWRITE ("Проверка статуса мисии")
   IF_PICTURE_IN (14,43, 1766,1018, "Accept 8.bmp", -1, 100)
      MOVE($_return1, $_return2)
      WAIT(1)
      LCLICK($_return1, $_return2)
      LOGWRITE ("Мисиия принята")
   else
      LOGWRITE ("Статус миссии - не известен")
   END_IF
   
   GETSCREEN
   COLORMODE(8, 51,43, 1766,1018)
   LOGWRITE ("Проверка расположения груза")
   //SCREENSHOTEX(14,43, 1766,1018)
   IF_PICTURE_IN (51,43, 1766,1018, "Okey 8.bmp", -1, 98)
      LOGWRITE ("Груз на станции")
      WAIT(1)
     
      GETSCREEN
      COLORMODE(8, 14,43, 1766,1018)
      LOGWRITE ("Прокладка маршрута доставки")
      //SCREENSHOTEX(14,43, 1766,1018)
      IF_PICTURE_IN (14,43, 1766,1018, "Place of delivery 8.bmp", -1, 95)
         MOVE($_return1+120, $_return2+3)
         WAIT(1)
         RCLICK($_return1+120, $_return2+3)
         WAIT(1)
         MOVE($_return1+200, $_return2+30)
         WAIT(1)
         LCLICK($_return1+200, $_return2+30)
         LOGWRITE ("Место доставки задано")
         
         
         LCLICK(952,16)  // 14865606
         GETSCREEN
         COLORMODE(6, 14,43, 1766,1018)
         LOGWRITE ("Окончание работы с агентом")
         //SCREENSHOTEX(14,43, 1766,1018)
         IF_PICTURE_IN (14,43, 1766,1018, "Window talk 6.bmp", -1, 99)
            MOVE($_return1+3, $_return2+3)
            WAIT(1)
            LCLICK($_return1+3, $_return2+3)
            GETSCREEN
            COLORMODE(5, 14,43, 1766,1018)
            IF_PICTURE_IN (14,43, 1766,1018, "X 5.bmp", -1, 99)
               MOVE($_return1+40, $_return2+4)
               WAIT(1)
               LCLICK($_return1+40, $_return2+4)
               LOGWRITE ("Закрыть окно разговора с агентом")
            else
               LOGWRITE ("ошибка не найден крест")
            END_IF
         else
            LOGWRITE ("ошибка не найдет разговор с агентом")
         END_IF
         
         LCLICK(952,16)  // 14865606
         GETSCREEN
         COLORMODE(6, 67,641, 280,921)
         LOGWRITE ("Погрузка товара")
         //SCREENSHOTEX(14,43, 1766,1018)
         IF_PICTURE_IN (67,641, 280,921, "Storage 6_1.bmp", -1, 90)
            MOVE($_return1+4, $_return2+4)
            WAIT(1)
            LCLICK($_return1+4, $_return2+4)
            MOVE(335,736)
            WAIT(1)
            LDOWN(335,736)
            WAIT(1)
            MOVE(124,691)
            WAIT(1)
            LUP(124,691)
            LOGWRITE ("Товар загружен")
         else
            LOGWRITE ("Ошибка проверки расположения груза")
         END_IF
         
         
         MOVE(1671,193)
         WAIT(2)
         LCLICK(1671,193)
         LOGWRITE ("Вылет")
         WAIT(15)
         qwer()
         
         
         LCLICK(867,22)
         GETSCREEN
         COLORMODE(8, 1018,359, 1081,402)
         LOGWRITE ("Проверка статуса миссии")
         IF_PICTURE_IN (1018,359, 1081,402, "Accept 8_2.bmp", -1, 100)
            MOVE($_return1, $_return2)
            WAIT(2)
            LCLICK($_return1, $_return2)
            LOGWRITE ("Мисиия принята")
            WAIT(1)
           
            GETSCREEN
            COLORMODE(8, 14,43, 1766,1018)
            SCREENSHOTEX(535,570, 662,595)
            LOGWRITE ("Проверка возможности сдачи миссии")
            IF_PICTURE_IN (14,43, 1766,1018, "Complete the mission.bmp", -1, 98)
               MOVE($_return1, $_return2)
               WAIT(2)
               LCLICK($_return1, $_return2)
               LOGWRITE ("Мисиия сдана успешно")
            else
               LOGWRITE ("Ошибка")
            END_IF
           
           
            WAIT(1)
            LCLICK(952,16)  // 14865606
            GETSCREEN
            COLORMODE(6, 14,43, 1766,1018)
            LOGWRITE ("Окончание работы с агентом")
            //SCREENSHOTEX(14,43, 1766,1018)
            IF_PICTURE_IN (14,43, 1766,1018, "Window talk 6.bmp", -1, 99)
               MOVE($_return1+3, $_return2+3)
               WAIT(1)
               LCLICK($_return1+3, $_return2+3)
               GETSCREEN
               COLORMODE(5, 14,43, 1766,1018)
               IF_PICTURE_IN (14,43, 1766,1018, "X 5.bmp", -1, 99)
                  MOVE($_return1+40, $_return2+4)
                  WAIT(1)
                  LCLICK($_return1+40, $_return2+4)
                  LOGWRITE ("Закрыть окно разговора с агентом")
               else
                  LOGWRITE ("ошибка не найден крест")
               END_IF
            else
               LOGWRITE ("ошибка не найдет разговор с агентом")
            END_IF
         END_IF
      else
         LOGWRITE ("Ошибка проверки статуса миссии")
      END_IF
   else
      LOGWRITE ("Груз в другом месте")
      GETSCREEN
      COLORMODE(8, 14,43, 1766,1018)
      LOGWRITE ("Проверка маршрута погрузки")
      //SCREENSHOTEX(14,43, 1766,1018)
      IF_PICTURE_IN (14,43, 1766,1018, "Place of loding.bmp", -1, 98)
         MOVE($_return1+120, $_return2+3)
         WAIT(2)
         RCLICK($_return1+120, $_return2+3)
         WAIT(2)
         MOVE($_return1+200, $_return2+30)
         WAIT(2)
         LCLICK($_return1+200, $_return2+30)
         LOGWRITE ("Место погрузки задано")
      else
         LOGWRITE ("ошибка")
         halt
      END_IF
     
      GETSCREEN
      COLORMODE(6, 14,43, 1766,1018)
      //SCREENSHOTEX(14,43, 1766,1018)
      LOGWRITE ("Окончание работы с агентом")
      IF_PICTURE_IN (14,43, 1766,1018, "Window talk 6.bmp", -1, 100)
         MOVE($_return1+3, $_return2+3)
         WAIT(2)
         LCLICK($_return1+3, $_return2+3)
         GETSCREEN
         COLORMODE(6, 14,43, 1766,1018)
         IF_PICTURE_IN (14,43, 1766,1018, "X.bmp", -1, 100)
            MOVE($_return1+1, $_return2+1)
            WAIT(2)
            LCLICK($_return1+1, $_return2+1)
            LOGWRITE ("Закрыть окно разговора с агентом")
         END_IF
      END_IF
      MOVE(1671,193)
      WAIT(2)
      LCLICK(1671,193)
      LOGWRITE ("Вылет")
      WAIT(15)
      qwer()
   END_IF
   
else
   LOGWRITE ("Начать разговор не найдено")
   LOGWRITE ("Поиск места назначения")
   IF_PICTURE_IN (65,65, 1755,1000, "set destination.bmp", -1, 85)
      MOVE($_return1, $_return2)
      WAIT(2)
      LCLICK($_return1, $_return2)
      LOGWRITE ("Задано место назначения агента")
      MOVE(1671,193)
      WAIT(2)
      LCLICK(1671,193)
      LOGWRITE ("Вылет")
      WAIT(15)
      qwer()
   else
      LOGWRITE ("Ошибка не найдено место назначение")
   END_IF
END_IF
//////COLORMODE(5, 1511,257, 1530,270)
/////8355711 - синий для мода 7, 16777215 - белый,  цвет скорости   диапазон 862,962, 874,984
/////2080703 цвет оверлея  диапазон 1511,257, 1530,270
Logged

vizaritm

  • Зашел в гости
  • *
  • Posts: 11
    • View Profile
Re: Помогите написать скрипт с циклом в цикле с IF_PIXEL_IN
« Reply #4 on: January 20, 2018, 01:33:34 PM »
можно конечно еще извратиться и дописать бота, раз есть массивы и потоки
Сейчас в Еве мини игра, пока летишь играешь. Игра про поиск планет по спадам светового излучения посредством перекрытия этими планетами светил. По факту горизонтальный ломаный амплитудный график, сезонные большие отклонения светила можно усреднить кнопкой, остаются мелкие, имеющие наверное какое-то усредненное значение, ну и наши отклонение усреднение отклонения на одном или нескольких участках с определенным шагом.
Ну и мои идеи, надо как то извратиться и поделить картинку на массив с шагом, считаем пиксели, делим на количество  участков, вставляем погрешность, считаем кол-во участков которые больше, если один - выделяем, если больше одного, условие на одинаковый шаг, с погрешностью - выделение.
Вообщем будет чем на следующий недели поломать голову, ну хотя бы с математической точки зрения.
Logged

Oraven

  • Супермодератор
  • Герой форума
  • *
  • Posts: 3685
  • Котэ
    • View Profile
Re: Помогите написать скрипт с циклом в цикле с IF_PIXEL_IN
« Reply #5 on: January 20, 2018, 02:19:02 PM »
Code: (clickermann) [Select]
$Найденый цвет = PXL(893,984)
LOGWRITE ("Найденый цвет:", $Найденый цвет)
IF_PIXEL_IN(893,984, 8355711)
Не стоит писать имена переменных кириллицей да еще и с пробелами.
Не верный синтаксис функции IF_PIXEL_IN. Должны быть указаны 4 числа области поиска а у тебя только 2.

Также нельзя выпрыгивать из циклов через гото. Не говоря уже что в данном случаи нет никакого цикла, если есть выход, если нет переход к метке. Просто убираем цикл и все становится правильным.
Там еще в одном месте у LOGWRITE не хватало кавычки.

Исправленный код
Code: (clickermann) [Select]
//=============================================
sub(qwer)
   LCLICK(944,17)  // Клик на окно
   WAIT(3)
   MOVE(1551,264)
   WAIT(3)
   LCLICK(1551,264)  // клик на чтроку оверлея
   WAIT(3)
   
   skip1:
   $check_yellow = 0
   WHILE($check_yellow = 0) // пока есть  желтый
      GETSCREEN
      COLORMODE(7, 655,46, 1717,1011)
      LOGWRITE ("Проверяем желтый варп")
      IF_PIXEL_IN(1511,257, 1530,270, 8388607, 8388350, 8388093) //Проверям желтый пиксель
         LOGWRITE ("Желтый варп найден")
         MOVE(1574,134)    //если есть: действие мышью
         WAIT(4)
         LCLICK(1574,134)
         WAIT(15)
         
         $check_blue = 0
         WHILE($check_blue = 0) // пока есть  синий ничего не делаем
            GETSCREEN
            COLORMODE(7, 890,970, 910,990)
            LOGWRITE ("Проверка синего")
            $color = PXL(893,984)
            LOGWRITE ("Найденый цвет:", $color)
            IF($color = 8355711)
               LOGWRITE ("Ожидание")
               WAIT(6)
            ELSE
               $check_blue = 1  //если нет:  возврат к проверке желтого пикселя
               LOGWRITE ("Синий не найден")
               WAIT(4)
            END_IF
         END_CYC
         
      else
         $check_yellow = 1 //Если нету: конец кольца
         LOGWRITE ("Желтый варп не  найден")
      END_IF
   END_CYC
   
   
   GETSCREEN
   COLORMODE(7, 1333,409 , 1482,460)
   LOGWRITE ("Проверка входа в док")
   IF_PICTURE_IN (1333,409, 1482,460, "Enter dock 7.bmp", -1, 90)
      MOVE($_return1, $_return2)
      WAIT(2)
      LCLICK($_return1, $_return2)
      LOGWRITE ("Вход в док")
      WAIT(15)
   ELSE
      LOGWRITE ("Вход в док не найден")
   END_IF
   
   GETSCREEN
   COLORMODE(8, 1623,167, 1708,215)
   LOGWRITE ("Проверка окончания стыковки")
   IF_PICTURE_IN (1623,167, 1708,215, "Exit 8.bmp", -1, 80)
      //  если есть: ничего не делаем
      WAITMS(100)
   ELSE
      WAIT(15)  //Если нет: ждем
      LOGWRITE ("Стыковка не окончена")
      goto(skip1)
   END_IF
   LOGWRITE ("Конец стыковки")
end_sub
//=============================================

LOGWRITE ("Начало скрипта")
LCLICK(867,22)  // 15128779

MOVE(754,122)
WAIT(1)
LCLICK(754,122)  // 3156759

GETSCREEN
COLORMODE(8, 45,45, 1700,1000)
LOGWRITE ("Проверка присутствия агента на стации")
IF_PICTURE_IN (1333,409 , 1482,460, "Talk 8.bmp", -1, 98)
   LOGWRITE ("Агент на базе - начать разговор")
   MOVE($_return1, $_return2)
   WAIT(1)
   LCLICK($_return1, $_return2)
   WAIT(1)
   
   GETSCREEN
   COLORMODE(8, 72,43, 1766,1018)
   LOGWRITE ("Проверка запросить задание")
   IF_PICTURE_IN (72,43, 1766,1018, "Requiest 8.bmp", -1, 100)
      LOGWRITE ("Удачно")
      WAITMS(100)
      MOVE($_return1, $_return2)
      WAIT(2)
      LCLICK($_return1, $_return2)
      WAIT(3)
   else
      LOGWRITE ("Не найдено")
   END_IF
   
   GETSCREEN
   COLORMODE(8, 72,43, 1766,1018)
   LOGWRITE ("Проверка просмотрара заданий")
   IF_PICTURE_IN (72,43, 1766,1018, "Look mission 8.bmp", -1, 100)
      LOGWRITE ("Удачно")
      WAITMS(100)
      MOVE($_return1, $_return2)
      WAIT(2)
      LCLICK($_return1, $_return2)
      WAIT(3)
   else
      LOGWRITE ("Не найдено")
   END_IF
   
   
   GETSCREEN
   COLORMODE(8, 14,43, 1766,1018)
   LOGWRITE ("Проверка статуса мисии")
   IF_PICTURE_IN (14,43, 1766,1018, "Accept 8.bmp", -1, 100)
      MOVE($_return1, $_return2)
      WAIT(1)
      LCLICK($_return1, $_return2)
      LOGWRITE ("Мисиия принята")
   else
      LOGWRITE ("Статус миссии - не известен")
   END_IF
   
   GETSCREEN
   COLORMODE(8, 51,43, 1766,1018)
   LOGWRITE ("Проверка расположения груза")
   //SCREENSHOTEX(14,43, 1766,1018)
   IF_PICTURE_IN (51,43, 1766,1018, "Okey 8.bmp", -1, 98)
      LOGWRITE ("Груз на станции")
      WAIT(1)
     
      GETSCREEN
      COLORMODE(8, 14,43, 1766,1018)
      LOGWRITE ("Прокладка маршрута доставки")
      //SCREENSHOTEX(14,43, 1766,1018)
      IF_PICTURE_IN (14,43, 1766,1018, "Place of delivery 8.bmp", -1, 95)
         MOVE($_return1+120, $_return2+3)
         WAIT(1)
         RCLICK($_return1+120, $_return2+3)
         WAIT(1)
         MOVE($_return1+200, $_return2+30)
         WAIT(1)
         LCLICK($_return1+200, $_return2+30)
         LOGWRITE ("Место доставки задано")
         
         
         LCLICK(952,16)  // 14865606
         GETSCREEN
         COLORMODE(6, 14,43, 1766,1018)
         LOGWRITE ("Окончание работы с агентом")
         //SCREENSHOTEX(14,43, 1766,1018)
         IF_PICTURE_IN (14,43, 1766,1018, "Window talk 6.bmp", -1, 99)
            MOVE($_return1+3, $_return2+3)
            WAIT(1)
            LCLICK($_return1+3, $_return2+3)
            GETSCREEN
            COLORMODE(5, 14,43, 1766,1018)
            IF_PICTURE_IN (14,43, 1766,1018, "X 5.bmp", -1, 99)
               MOVE($_return1+40, $_return2+4)
               WAIT(1)
               LCLICK($_return1+40, $_return2+4)
               LOGWRITE ("Закрыть окно разговора с агентом")
            else
               LOGWRITE ("ошибка не найден крест")
            END_IF
         else
            LOGWRITE ("ошибка не найдет разговор с агентом")
         END_IF
         
         LCLICK(952,16)  // 14865606
         GETSCREEN
         COLORMODE(6, 67,641, 280,921)
         LOGWRITE ("Погрузка товара")
         //SCREENSHOTEX(14,43, 1766,1018)
         IF_PICTURE_IN (67,641, 280,921, "Storage 6_1.bmp", -1, 90)
            MOVE($_return1+4, $_return2+4)
            WAIT(1)
            LCLICK($_return1+4, $_return2+4)
            MOVE(335,736)
            WAIT(1)
            LDOWN(335,736)
            WAIT(1)
            MOVE(124,691)
            WAIT(1)
            LUP(124,691)
            LOGWRITE ("Товар загружен")
         else
            LOGWRITE ("Ошибка проверки расположения груза")
         END_IF
         
         
         MOVE(1671,193)
         WAIT(2)
         LCLICK(1671,193)
         LOGWRITE ("Вылет")
         WAIT(15)
         qwer()
         
         
         LCLICK(867,22)
         GETSCREEN
         COLORMODE(8, 1018,359, 1081,402)
         LOGWRITE ("Проверка статуса миссии")
         IF_PICTURE_IN (1018,359, 1081,402, "Accept 8_2.bmp", -1, 100)
            MOVE($_return1, $_return2)
            WAIT(2)
            LCLICK($_return1, $_return2)
            LOGWRITE ("Мисиия принята")
            WAIT(1)
           
            GETSCREEN
            COLORMODE(8, 14,43, 1766,1018)
            SCREENSHOTEX(535,570, 662,595)
            LOGWRITE ("Проверка возможности сдачи миссии")
            IF_PICTURE_IN (14,43, 1766,1018, "Complete the mission.bmp", -1, 98)
               MOVE($_return1, $_return2)
               WAIT(2)
               LCLICK($_return1, $_return2)
               LOGWRITE ("Мисиия сдана успешно")
            else
               LOGWRITE ("Ошибка")
            END_IF
           
           
            WAIT(1)
            LCLICK(952,16)  // 14865606
            GETSCREEN
            COLORMODE(6, 14,43, 1766,1018)
            LOGWRITE ("Окончание работы с агентом")
            //SCREENSHOTEX(14,43, 1766,1018)
            IF_PICTURE_IN (14,43, 1766,1018, "Window talk 6.bmp", -1, 99)
               MOVE($_return1+3, $_return2+3)
               WAIT(1)
               LCLICK($_return1+3, $_return2+3)
               GETSCREEN
               COLORMODE(5, 14,43, 1766,1018)
               IF_PICTURE_IN (14,43, 1766,1018, "X 5.bmp", -1, 99)
                  MOVE($_return1+40, $_return2+4)
                  WAIT(1)
                  LCLICK($_return1+40, $_return2+4)
                  LOGWRITE ("Закрыть окно разговора с агентом")
               else
                  LOGWRITE ("ошибка не найден крест")
               END_IF
            else
               LOGWRITE ("ошибка не найдет разговор с агентом")
            END_IF
         END_IF
      else
         LOGWRITE ("Ошибка проверки статуса миссии")
      END_IF
   else
      LOGWRITE ("Груз в другом месте")
      GETSCREEN
      COLORMODE(8, 14,43, 1766,1018)
      LOGWRITE ("Проверка маршрута погрузки")
      //SCREENSHOTEX(14,43, 1766,1018)
      IF_PICTURE_IN (14,43, 1766,1018, "Place of loding.bmp", -1, 98)
         MOVE($_return1+120, $_return2+3)
         WAIT(2)
         RCLICK($_return1+120, $_return2+3)
         WAIT(2)
         MOVE($_return1+200, $_return2+30)
         WAIT(2)
         LCLICK($_return1+200, $_return2+30)
         LOGWRITE ("Место погрузки задано")
      else
         LOGWRITE ("ошибка")
         halt
      END_IF
     
      GETSCREEN
      COLORMODE(6, 14,43, 1766,1018)
      //SCREENSHOTEX(14,43, 1766,1018)
      LOGWRITE ("Окончание работы с агентом")
      IF_PICTURE_IN (14,43, 1766,1018, "Window talk 6.bmp", -1, 100)
         MOVE($_return1+3, $_return2+3)
         WAIT(2)
         LCLICK($_return1+3, $_return2+3)
         GETSCREEN
         COLORMODE(6, 14,43, 1766,1018)
         IF_PICTURE_IN (14,43, 1766,1018, "X.bmp", -1, 100)
            MOVE($_return1+1, $_return2+1)
            WAIT(2)
            LCLICK($_return1+1, $_return2+1)
            LOGWRITE ("Закрыть окно разговора с агентом")
         END_IF
      END_IF
      MOVE(1671,193)
      WAIT(2)
      LCLICK(1671,193)
      LOGWRITE ("Вылет")
      WAIT(15)
      qwer()
   END_IF
   
else
   LOGWRITE ("Начать разговор не найдено")
   LOGWRITE ("Поиск места назначения")
   IF_PICTURE_IN (65,65, 1755,1000, "set destination.bmp", -1, 85)
      MOVE($_return1, $_return2)
      WAIT(2)
      LCLICK($_return1, $_return2)
      LOGWRITE ("Задано место назначения агента")
      MOVE(1671,193)
      WAIT(2)
      LCLICK(1671,193)
      LOGWRITE ("Вылет")
      WAIT(15)
      qwer()
   else
      LOGWRITE ("Ошибка не найдено место назначение")
   END_IF
END_IF
//////COLORMODE(5, 1511,257, 1530,270)
/////8355711 - синий для мода 7, 16777215 - белый,  цвет скорости   диапазон 862,962, 874,984
/////2080703 цвет оверлея  диапазон 1511,257, 1530,270
Logged

vizaritm

  • Зашел в гости
  • *
  • Posts: 11
    • View Profile
Re: Помогите написать скрипт с циклом в цикле с IF_PIXEL_IN
« Reply #6 on: January 20, 2018, 02:49:56 PM »
Спс
Logged
Pages: [1]
« previous next »