Как создать переменную с рондомным результатом?

[Hito]

Ребят, вот код:

Code: (clickermann) [Select]

KEYDOWN(#SHIFT)
WAITMS(100)
KEYPRESS(rnd (#A, #Z)
WAITMS(50)
KEYUP(#SHIFT)
WAITMS(100)
KEYPRESS(rnd (#A, #Z)
WAITMS(100)
KEYPRESS(rnd (#A, #Z)
WAITMS(100)
KEYPRESS(rnd (#A, #Z)
WAITMS(100)
KEYPRESS(rnd (#A, #Z)
WAITMS(100)
Как, после того, как он введет РОНДОМНЫХ пять букв, записать результат в переменную?

[Oraven]

Что опять за бред?!

Вот

Code: (clickermann) [Select]

$l = 5  // длина слова
$s = "ABCDEFGHIJKLMNOPQRSTUVWXYZ" // набор символов
$pass = ""
FOR($i=0, $i<$l)
   $pass = STRCONCAT($pass, STRCUT($s, RND(1,STRLEN($s)), 1))
END_CYC
LOGWRITE($pass)

KEYSTRING($pass) // ввод слова

HALT
Если нужно именно с большой буквы то вот

Code: (clickermann) [Select]

$l = 5  // длина слова
$s = "ABCDEFGHIJKLMNOPQRSTUVWXYZ" // набор символов
$pass = ""
FOR($i=0, $i<$l)
   $pass = STRCONCAT($pass, STRCUT($s, RND(1,STRLEN($s)), 1))
END_CYC
LOGWRITE($pass)

KEYDOWN(#SHIFT)
WAITMS(50)
KEYSTRING(STRCUT($pass,1,1)) // ввод слова
KEYUP(#SHIFT)
WAITMS(50)
KEYSTRING(STRCUT2($pass,2,STRLEN($pass))) // ввод слова
WAITMS(100)

HALT

[Hito]

Огромное СПС!