Провести

[SimplY]

1) Помогите вычленить имя и отчество. Имя и отчество всегда в конце! Другими словами, вычленить 2 последних слова, сколько бы слов в тексте ни было.

Code: (clickermann) [Select]

UNDEFINE($fio)
STRSEPARATE($f, " ", $fio)
IF(ARRSIZE($fio) > 2)
   $io = STRCONCAT($fio[1], " ", $fio[2])
END_IF
TOCLIP(STRCONCAT($io, ", хорошего дня. Отправляю вам во вложении информацию о нашем заводе и продукции. Прошу ответным письмом дать обратную связь."))
Примеры:
Специалист Петров Иван Иванович
Результат: Иван Иванович

Главный специалист Иванов Иван Иванович
Результат: Иван Иванович

Данный код вычленяет, только если в тексте 3 слова.

2) Делать математические вычисления в переменной
Скопировал число. Например, 200,25.
Всплывает диалоговое окно ввода строки. Сколько % отнять? Далее из этого числа отнимает этот % с копейками.
Например, выделил число 200,25
В диалоговом окне ввел 25.
Кликер умножает в диалоговом окне на 0.75.
Результат 150,1875
Округляет копейки до целого рубля. Получается 151
Обратно вставляет 151,00.

Code: (clickermann) [Select]

FOR($a=0,$a<3)
   LCLICK(1162,602)  // Выделить число
   WAITMS(40)
END_CYC
WAITMS(400)
KEYDOWN (#CTRL)
WAITMS (50)
KEYPRESS (#C)
KEYUP (#CTRL)
$cena = FROMCLIP() // Число
WAITMS(400)
INPUTBOX("Сколько % отнять?", "10", 10)
$procent

//Операция с числом. $procent - это тот %, который будет отниматься.

TOCLIP($cena)
KEYDOWN (#CTRL)
WAITMS (50)
KEYPRESS (#V)
KEYUP (#CTRL)

[Vint]

1.

Code: (clickermann) [Select]

$t = "Главный специалист Иванов Иван Иванович"

UNDEFINE($sep)
STRSEPARATE($t, " ", $sep)

IF(ARRSIZE($sep) > 1)
    $IO = STRCONCAT($sep[ARRSIZE($sep)-2], " ", $sep[ARRSIZE($sep)-1])
    LOGWRITE($IO)
    TOCLIP(STRCONCAT($IO, ", хорошего дня. Отправляю вам во вложении информацию о нашем заводе и продукции. Прошу ответным письмом дать обратную связь."))
END_IF

HALT
2.

Code: (clickermann) [Select]

FOR($a=0, $a < 3)
    LCLICK(1162,602)  // Выделить число
    WAITMS(40)
END_CYC
WAITMS(400)
KEYDOWN(#CTRL)
WAITMS(50)
KEYPRESS(#C)
KEYUP(#CTRL)
WAITMS(150)
$cena = FROMCLIP()
WAITMS(150)
$procent = INPUTBOX("Сколько % отнять?", "10", 10)

//Операция с числом. $procent - это тот %, который будет отниматься.
$cena = STRREPLACE($cena, ",", ".")
$cena = INT($cena - ($cena*$procent/100) + 0.99999999999)
LOGWRITE($cena)

TOCLIP($cena)
KEYDOWN(#CTRL)
WAITMS(50)
KEYPRESS(#V)
KEYUP(#CTRL)
Код для теста

Code: (clickermann) [Select]

$cena = "200,25"

WAITMS(150)
$procent = INPUTBOX("Сколько % отнять?", "25", 10)

//Операция с числом. $procent - это тот %, который будет отниматься.
$cena = STRREPLACE($cena, ",", ".")
$cena = INT($cena - ($cena*$procent/100) + 0.99999999999)
LOGWRITE($cena)

HALT

[Oraven]

1

Code: (clickermann) [Select]

UNDEFINE($fio)
STRSEPARATE($f, " ", $fio)
$sz = ARRSIZE($fio)
IF($sz > 2)
   $io = STRCONCAT($fio[$sz-2], " ", $fio[$sz-1])
END_IF
TOCLIP(STRCONCAT($io, ", хорошего дня. Отправляю вам во вложении информацию о нашем заводе и продукции. Прошу ответным письмом дать обратную связь."))

2

Code: (clickermann) [Select]

$cena = STRREPLACE(FROMCLIP(),",",".") // Число
$procent = INT(INPUTBOX("Сколько % отнять?", "10", 999))
$cena = $cena-(($cena/100)*$procent) // Операция с числом. $procent - это тот %, который будет отниматься.
IF(STRPOS($cena, ".") > 0)
   $cena = INT($cena)+1
END_IF
$cena = STRCONCAT($cena, ",00")
TOCLIP($cena)