// 17.10.2016
// скрипт для "Clickermann v.4.12"
// автор - Золотой
// предназначен для постоянной работы в фоновом режиме,
//на отдельнозапущеном кликере и управляется мышью И ДИАЛОГОВЫМИ ОКНАМИ
#name "СКРИНЫ v1.0"
// ЗАПУСК - нажатием средней кнопки мыши
// нажатие левой кнопки мыши- указывает первый угол
// отпускание ЛКМ - указывает второй угол
// скрин делается "перетаскиванием"
// Н А С Т Р О Й К И
// внимание создайте в папке со скриптом папку "мои скрины" или укажите путь к вашей папке по умолчанию
// будет ошибка интерпритации если сохраняет в несуществующую папку!
$papka= "мои скрины" //укажите папку по умолчанию, если нужно и путь к ней\
$nam= "Скрин_" //укажите название по умолчанию
$zapr_papka=1 // 0 - запрашивать папку для сохранения, 1- сохранять в папку по умолчанию
// ВНИМАНИЕ! Если при сохранении указывать название уже существующих скринов, они будут заменены новыми
$nam_avto=2 // 0 - запрашивать имя скринов ,1- номеровать по порядку автоматически , 2- называть случайно( защита от затирания существующих скринов)
$color = 0 // 0 - запрашивать уровень COLORMODE, 1-8 использовать указанный
$sohr = 0 // 0 - запрашивать какие скрины сохранять, 1- обычный скрин, 2- с цветокоррекцией, 3- оба скрина
//=============================================
IF(iskeydown(4)=1) // запуск нажатием средней кнопки мыши
SWITCH($nam_avto)
CASE(0)
$nam=INPUTBOX("Введите имя файла", $nam, 20)
CASE(1)
INC($var,1)
$nam=STRCONCAT($nam,$var)
DEFAULT
RND(1,5)
$nam=STRCONCAT($nam,RND(1,1000000))
END_SWITCH
IF($zapr_papka=0)
$papka=INPUTBOX("укажите папку для сохранения",$papka, 20)
END_IF
IF($sohr=0)
$sohr = radiobox("Выберете какие скрины сохранять, CANCEL - оставит только 1 оригинал ","обычный скрин","с цветокоррекцией","оба скрина")
END_IF
IF(($color=0)&($sohr!1))
$color = radiobox("Выберете режим CLORMODE, CANCEL - оставит только 1 оригинал ","1","2","3","4","5","6","7","8")
END_IF
HINTPOPUP ("нажмите ЛКМ на первом углу")
WHILE(iskeydown(1)=0) // ждёт нажатие левой кнопки мыши- указывает первый угол
WAITMS(50)
END_CYC
$x1=$_xmouse
$y1=$_ymouse
HINTPOPUP ("отпустите ЛКМ на втором углу",STRCONCAT("верх ",$vx," ",$vy))
WHILE(iskeydown(1)=1) // ждёт отпускание ЛКМ - указывает второй угол
WAITMS(100)
$x2=$_xmouse
$y2=$_ymouse
IF($x1>$x2)
$vx=$x2
$nx=$x1
ELSE
$vx=$x1
$nx=$x2
END_IF
IF($y1>$y2)
$vy=$y2
$ny=$y1
ELSE
$vy=$y1
$ny=$y2
END_IF
$rx=$nx-$vx
$ry=$ny-$vy
// в рабочем окне показывает размеры будущего скрипта
LOGWRITE (STRCONCAT(" размеры: ", $rx," на ",$ry, " пикселей"))
END_CYC
GETSCREEN($vx,$vy,$nx,$ny)
// LOGWRITE ($vx," ",$vy," ",$nx," ",$ny," ")
IF($sohr!2)
// ошибка интерпритации если указана несуществующая папка
SCREENSHOTFIX($vx,$vy,$nx,$ny,STRCONCAT($papka,"\",$nam,".bmp"))
END_IF
HINTPOPUP(STRCONCAT("скрин - "$papka,$nam,".bmp"),STRCONCAT("размеры: ", $rx," на ",$ry, " пикселей"))
IF(($color!0)&($sohr!1))
COLORMODE($color,$vx,$vy,$nx,$ny)
SCREENSHOTFIX($vx,$vy,$nx,$ny,STRCONCAT($papka,"\",$nam,"_",$color,".bmp"))
END_IF
BEEP(800,200) // звуковой сигнал, скрипты готовы.
LOGCLEAR
END_IF
