Типовые алгоритмы, вводные статьи (Новички, читайте!)

[ЦИТРИН]

В теме "Предложения по применению от новичков."  Сергей  написал интересный  скрипт,  который  позволяет ставить дату и время  в удобочитаемом формате.   http://clickermann.tk/forum/index.php?topic=36.msg373#msg373
 Нельзя ли его перенести сюда , в шапку примеров?
На этом примере новичкам можно показать, как работает функция  инклуд.

[Oraven]

Скрипт включает действия в определенное время.
IF_TIME("*:*:*"). Звездочка означает любой час, любую минуту и секунду.

IF_TIME("12:00:00") // сработает в 12:00:00
END_IF

Пример:

Code: [Select]

IF_TIME("12:10:*") // Включаем в 12.10
$t1 = 1
END_IF

IF_TIME("16:10:*") // Отключаем в 16.10
$t1 = 0
END_IF


IF_TIME("16:10:*") // Включаем в 16.10
$t2 = 1
END_IF

IF_TIME("12:10:*") // Отключаем в 12.10
$t2 = 0
END_IF


IF($t1 = 1) // 12.10
// здесь Действие 
// Будет выполняться с 12.10 по 16.10
LOGWRITE("Задание в 12.10")
END_IF

IF($t2 = 1) // 16.10
// здесь Действие
// Будет выполняться с 16.10 по 12.10
LOGWRITE("Задание в 16.10")
END_IF

WAITMS (500)

[Johnny]

Написание подпрограммы для вычисления даты
Пример создания пользовательских подпрограмм и их подключения через директиву include
Оригинальный пост пользователя Сергей: http://clickermann.tk/forum/index.php?topic=36.msg373#msg373

Данный пример раскрывает возможность "прятать от глаз" большой громоздкий код в программные библиотеки.
Имеется задача: вычислить текущую дату на основании системной переменной $_time_t
Для этого была написана следующая подпрограмма, для удобства вынесенная в отдельный файл date.cms

date.cms

Code: (clickermann) [Select]

// Day, Month, Year from $_time_t
// Author: Sergey
// Version: 1.0 (30.10.2012)

SUB(UPDATE_DATE)
   $_date_y = 1970
   $_date_m = 1
   $_date_d = ROUND(($_time_t / (3600 * 24)) - $voi, 0) + 1//floor
   $voi = 0.499999999999
   $break = 0
   
   WHILE($break = 0)
      $arg1 = $_date_y-1968
      $arg2 = 4
      IF($arg1-(ROUND(($arg1/$arg2)-$voi,0)*$arg2) = 0)//mod($_date_y-1968, 4) = 0
         $nd = 366
      ELSE
         $nd = 365
      END_IF
     
      if($_date_d > $nd)
         INC($_date_d, 0-$nd)
         INC($_date_y, 1)
      ELSE
         $break = 1
      END_IF
   END_CYC
   $break = 0
   
   WHILE($break = 0)
      $arg1 = $_date_y-1968
      $arg2 = 4
      IF( ($arg1-(ROUND(($arg1/$arg2)-$voi,0)*$arg2) = 0) & ($_date_m = 2) )//(mod($_date_y-1968, 4) = 0) & ($_date_m = 2)
         $nd = 29
      ELSE
         $nd = STRCUT("31,28,31,30,31,30,31,31,30,31,30,31", (($_date_m-1) * 3) + 1, 2)
      END_IF
      IF($_date_d > $nd)
         INC($_date_d, 0-$nd)
         INC($_date_m, 1)
      ELSE
         $break = 1
      END_IF
   END_CYC
END_SUB

GOSUB(UPDATE_DATE)
После вызова эта подпрограмма создает следующие переменные, которые могут использоваться в вашей программе

• $_date_d - День
• $_date_m - Месяц
• $_date_y - Год

Пример использования подпрограммы

Code: (clickermann) [Select]

// Подключаем файл, содержащий подпрограмму UPDATE_DATE, это работает так же, как если бы вы просто скопировали все содержимое файла date.cms за место этой строчки
#include "date.cms" 

print($_date_d,".",$_date_m,".",$_date_y) // Выводим "старую" дату

GOSUB(UPDATE_DATE) // Вызов подпрограммы (напоминаю что ее "тело" находится в подключенном файле date.cms), обновление переменных
print($_date_d,".",$_date_m,".",$_date_y) // Выводим актуальную дату

HALT
Этот пример вы можете скачать из вложения

Ах да, скрипт не будет работать если вы изобрели машину времени и переместились раньше 1970 года.
Отдельное спасибо Ляпису за идею с обходом отсутствия массивов.

[Сергей]

Хм, а почему в справке о условии IF_TIME нигде не написано?

[Johnny]

Хм, а почему в справке о условии IF_TIME нигде не написано?

потому что я думал что удалил его уже давно. очередной костыль из серии if_что-то. неправильно все это.
пользуйтесь переменными

кто спойлеры просил.
[spoiler=вот есть пока такие]
потом может доработаю
сейчас надо другие дела поделать
[/spoiler]

[Oraven]

Скрипт выполняет действия в разные промежутки времени

1 действие 1 раз в 30 секунд
2 действие 1 раз в 1 минуту
3 действие 1 раз в 2 минуты

$_time_t - это системная переменная. При каждом обращении к ней возвращает текущее время в формате Unix-систем
Отсчет времени идет в секундах. А если нужно использовать миллисекунды то в место $_time_t пишем $_ms - Системный таймер Windows.
Имя переменных $time1, $time2 и тд. может быть любым.

Code: (clickermann) [Select]

// ПЕРВОЕ ДЕЙСТВИЕ РАЗ В 30 СЕКУНД
IF($time1 < $_time_t) // условие сработает если переменная $time1 меньше $_time_t
$time1 = $_time_t + 30 // записываем в переменную $time1 текущее время + 30 секунд

// Здесь пишутся необходимые действия

END_IF // конец первого условия

// ВТОРОЕ ДЕЙСТВИЕ РАЗ В 1 МИНУТУ
IF($time2 < $_time_t)
$time2 = $_time_t + 60

// Здесь пишутся необходимые действия

END_IF // конец второго условия

// ТРЕТЬЕ ДЕЙСТВИЕ РАЗ В 2 МИНУТЫ
IF($time3 < $_time_t)
$time3 = $_time_t + 120

// Здесь пишутся необходимые действия

END_IF // конец третьего условия

// вне условий можно написать действия которые должны выполняться постоянно

WAITMS (500) // задержка скрипта 500 мс для разгрузки процессора

Также, время следующего срабатывания может записываться в файл ini.
Это важно если действия выполняются, например, раз в час или еще дольше, можно остановить кликер, и таймеры не собьются.
INT и STRCONCAT я использовал чтобы кликер при отсутствии файла time.ini не выдавал ошибок (вернет 0 если строки или файла не существует)

Code: (clickermann) [Select]

// Эти строки выполняются при запуске 1 раз
$time1 = INT(STRCONCAT ("0", INIREAD ("time.ini", "Time1", "TIME")))
$time2 = INT(STRCONCAT ("0", INIREAD ("time.ini", "Time2", "TIME")))
$time3 = INT(STRCONCAT ("0", INIREAD ("time.ini", "Time3", "TIME")))

go: // далее произойдет зацикливание до метки GO

IF($time1 < $_time_t)
$time1 = $_time_t + 30
INIWRITE ("time.ini", "Time1", $time1, "TIME") // запись в файл time.ini времени следующего срабатывания условия

// Здесь пишутся необходимые действия

END_IF

IF($time2 < $_time_t)
$time2 = $_time_t + 60
INIWRITE ("time.ini", "Time2", $time2, "TIME")

// Здесь пишутся необходимые действия

END_IF

IF($time3 < $_time_t)
$time3 = $_time_t + 120
INIWRITE ("time.ini", "Time3", $time3, "TIME")

// Здесь пишутся необходимые действия

END_IF

WAITMS (500)

goto(go) // переход к метке GO


[Oraven]

Перезагрузить или выключить компьютер.

Для этого пишем такие строки

Отключение компьютера

Code: (clickermann) [Select]

EXECUTE ("shutdown.exe", "/s /t 00")
HALT
Отключение компьютера с принудительным завершением приложений без предварительного предупреждения

Code: (clickermann) [Select]

EXECUTE ("shutdown.exe", "/s /f /t 00")
HALT
Перезагрузка компьютера

Code: (clickermann) [Select]

EXECUTE ("shutdown.exe", "/r /t 00")
HALT
Обозначения:
/l                      Выход (Log off)
/s                     Завершение работы компьютера
/r                     Перезагрузка компьютера
/a                    Прекращение завершения работы системы
/t xx                Таймаут завершения работы - xx сек.
/f                     Принудительное завершение приложений без предварительного предупреждения

[Oraven]

Как нажать Ctrl+V в оконном режиме?

Вариант 1

Code: (clickermann) [Select]

TOCLIP ("Тест") // отправляем текст в буфер
SENDMESSAGE ($_hwnd, 0x0302, 0, 0) //Посылаем окну команду "Вставить из буфера"
halt // стоп
Если не работает используем другой способ.
Вариант 2

Code: (clickermann) [Select]

TOCLIP ("Тест") // отправляем текст в буфер
WAITMS (50)

$hwnd = $_hwnd // записываем в переменную $hwnd текущий HWND окна
HSET ($hwnd,0) // отключаем оконный режим
KEYDOWN (#CTRL) // зажимаем Ctrl
HSET ($hwnd,1) // снова включаем оконный режим
WAITMS (20)
KEYPRESS (#V) // отправляем окну нажатие клавиши V
HSET ($hwnd,0) // отключаем оконный режим
KEYUP (#CTRL) // отпускаем Ctrl
HSET ($hwnd,1) // снова включаем оконный режим
halt // стоп

[Vint]

Люди, товарищи, граждане, господа...
Есть ли у кого решение известного языкового бага/особенности. Надоело следить за раскладкой в самом Кликермэне. Да и не всегда это возможно, если кровь из носа, а нужно использовать оба языка в одном скрипте.
Ситуацию бы спасло исправление работы программы или хотя бы костыли для этого + (как здесь предлагали) функция (переменная?) для определения раскладки в целевом окне.

Если кто-то решил проблему, поделитесь пожалуйста.

[Сергей]

Да проблему сейчас твердо никак не решить, только если при включении скрипта следить за раскладкой. Нужно конечно переменную в которой находится текущая раскладка, по другому никак.

[Vint]

Джонни, а нельзя по аналогии POSTMESSAGE на WinAPI ввести функцию
LoadKeyboardLayout - загрузить новую раскладку
достаточно будет её одной, ну для полной нирваны можно ещё
GetKeyboardLayout - определить текущую раскладку

Заранее извиняюсь если сморозил чушь, в WinAPI ничего не понимаю, просто искал информацию по POSTMESSAGE и обратил внимание.

[Сергей]

Да надо просто ввести системную переменную $_kblayout и помещать в нее раскладку текущего окна при обращении к ней.

[СлавьЯнИнъ]

Друзья, всем привет ))

Возникает вопрос по посту - Написание подпрограммы для вычисления даты
У меня в данный момент вычисляет 7.12.2012.
Как вылечить, где править, может корректировку GMT поставить?
Но не в одной корректировке пояса дело.

[Сергей]

СлавьЯнИнъ, а какое у тебя время?
Он по идее должен выдавать дату которая стоит у тебя на компьютере. В $_time_t кладется время прошедшее с 1 января 1970 года без поправок на часовой пояс, т.е. время когда этот момент настал именно в твоем часовом поясе.
Так выдает виндовс, и так выдает и кликерман.
Хотя велика вероятность что проблема в алгоритме, мог где-нибудь ошибиться.

[СлавьЯнИнъ]

Применено:
GOSUB(UPDATE_DATE)
print($_date_d,".",$_date_m,".",$_date_y)
GOSUB(UPDATE_DATE)
print($_date_d,".",$_date_m,".",$_date_y)

получено:
1. Если время с 00:00 до 12:59 то
оба принта с правильным числом
2. Если время с 13:00 до 23:59 то
первый принт показывает число на 1 больше, а второй нормальное.

Вот и гадать теперь где там эта ошибка ?? ((