Клики в заданные области экрана определенное количество раз

[kassmaster]

Помогите пожалуйста разобраться, есть потребность кликать скажем в 4 области экрана рандомно, но не более одного клика по каждой области. Как это осуществить?

[Oraven]

Пример:
143,55  - верхний левый угол
350,219 - нижний правый угол

Code: (clickermann) [Select]

LCLICK(RND(143,350),RND(55,219))
WAITMS(100)

LCLICK(RND(670,840),RND(79,276))
WAITMS(100)

LCLICK(RND(1091,1317),RND(76,268))
WAITMS(100)

LCLICK(RND(1045,1232),RND(836,987)) 
WAITMS(100)

HALT

[kassmaster]

Спасибо за ответ, это понятно.
Задача в том, чтобы перемешать последовательность кликов по областям.

[Hito]

Как-то так что ль...?

Code: (clickermann) [Select]

IF($start = 0)
   $x[0] = // Кордината x первого клика
   $y[0] = // Координата y первого клика
   
   $x[1] = // Кордината x второго клика
   $y[1] = // Координата y второго клика
   
   $x[2] = // Кордината x третьего клика
   $y[2] = // Координата y третьего клика
   
   $x[3] = // Кордината x четвертого клика
   $y[3] = // Координата y четвертого клика
   
   $start = 1
END_IF


$kblmn = 0
WHILE($kblmn = 0)
   $num_klick = RND(0,3)
   IF($num_klick ! $proshliy_num_click)
      $proshliy_num_click = $num_klick
      $kblmn = 1
   END_IF
   WAITMS(5)
END_CYC

LCLICK($x[$num_klick],$y[$num_klick])
WAITMS(100)

[BiG]

Вроде так
10,30 - верхний левый
20,40 - нижний правый

Code: (clickermann) [Select]

$var=rnd(1,4)
IF($var ! $var1)
   SWITCH($var)
      CASE(1)
         LCLICK(rnd(10,20),rnd(30,40))
         
      CASE(2)
         LCLICK(rnd(50,60),rnd(70,80))
         
      CASE(3)
         LCLICK(rnd(90,100),rnd(110,120))
         
      CASE(4)
         LCLICK(rnd(130,140),rnd(150,160))
   END_SWITCH
   $var1 = $var // Не кликать в тот же сектор
END_IF
waitms(1000)

[Oraven]

Code: (clickermann) [Select]

$r = "1234"
$c = 0
WHILE($c = 0)
   $n = INT(STRCUT($r,RND(1,STRLEN($r)),1))
   IF(STRLEN($r) > 1)
      $r = INT(STRFILTER ($r, $n, 0))
   Else
      $c = 1
   END_IF
   SWITCH($n)
      CASE(1)
         LCLICK(RND(143,350),RND(55,219))
      CASE(2)
         LCLICK(RND(670,840),RND(79,276))
      CASE(3)
         LCLICK(RND(1091,1317),RND(76,268))
      CASE(4)
         LCLICK(RND(1045,1232),RND(836,987))
   END_SWITCH
   WAITMS(100)
END_CYC

HALT

[kassmaster]

Спасибо большое, очень помогли