Author Topic: Подскажите пожалуйста как сделать такой анализ  (Read 2421 times)

0 Members and 1 Guest are viewing this topic.

d2_bot

  • Освоившийся
  • **
  • Posts: 85
    • View Profile
Всем привет, есть скрипт для игрового автомата
Который в работе опирается на 2 цвета, красный и зеленый



Code: [Select]
waitms(300)
GETSCREEN
IF_PICTURE_IN (493,368, 498,374, "green.bmp")
waitms(50)
move(401,347)
waitms(300)
DBLCLICK(401,347)   // MIn
waitms(500)

 

 

 $r = RND(1,2)
SWITCH($r)
CASE(1)
 MOVE(562,332)
   waitms(300)
LCLICK(562,332)   // BET1


CASE(2)
 MOVE(701,332)
   waitms(300)
LCLICK(701,332)   // BET2




END_SWITCH
WAIT(2)



 
waitms(rnd(500,800)))
else
GETSCREEN
IF_PICTURE_IN (493,368, 498,374, "red.bmp")
waitms(50)
MOVE(366,347)
   waitms(300)
LCLICK(366,347)  // X2
  waitms(500)


 $r = RND(1,2)
SWITCH($r)
CASE(1)
 MOVE(562,332)
   waitms(300)
LCLICK(562,332)   // BET1


CASE(2)
 MOVE(701,332)
   waitms(300)
LCLICK(701,332)   // BET2


waitms(rnd(500,800))
end_if


Скрипт ищет наличие красной или зеленой полоски, в зависимости от цвета выполняются дальнейшие действия:
зеленый - сбрасываем ставку и начинаем с минимума
красный - делаем х2 ставку, пока не появится зеленый

Очень хотелось бы настроить скрипт так, чтобы при выпадении красного N раз подряд
происходил сброс ставок(как при зеленом цвете)
Помогите пожалуйста как реализовать можно

Vint

  • Супермодератор
  • Герой форума
  • *
  • Posts: 3935
  • Лечу куда хочу. cman 4.13.014x32, 4.14.003 W10
    • View Profile
Ох уж эти красно-зелёные удваивания... Как они достали  :)

Для начала верни потерявшийся END_SWITCH и END_IF. Убери лишнюю скобку в waitms(rnd(500,800))) и один лишний GETSCREEN

Заведи переменную в которой будешь считать выпадение красного. При выпадении красного, сначала проверять её и при действии наращивать.
Ну и сбрасывать при достижении N.
Вынести действия по "зелёному" (да и красному можно)  в подпрограмму - для удобного управления дальнейшими действиями.
« Last Edit: November 19, 2019, 10:43:59 AM by Vint »


Vint

  • Супермодератор
  • Герой форума
  • *
  • Posts: 3935
  • Лечу куда хочу. cman 4.13.014x32, 4.14.003 W10
    • View Profile
Типа такого:
Code: (clickermann) [Select]
SUB(bet)
    $r = RND(1,2)
    SWITCH($r)
        CASE(1)
            MOVE(562,332)
            WAITMS(300)
            LCLICK(562,332)   // BET1
        CASE(2)
            MOVE(701,332)
            WAITMS(300)
            LCLICK(701,332)   // BET2
    END_SWITCH
    WAITMS(rnd(2500, 2800))
END_SUB

SUB(move_click, $xx, $yy, $dbl)
    WAITMS(50)
    MOVE($xx, $yy)
    WAITMS(300)
    LCLICK($xx, $yy)
    IF($dbl)
        WAITMS(100)
        LCLICK($xx, $yy)
    END_IF
    WAITMS(500)
END_SUB

SUB(green)
    move_click(401, 347, 1)   // MIn
    bet()
END_SUB

SUB(red)
    move_click(366, 347, 0)  // X2
    bet()
END_SUB


DEFINE($N, 7)
DEFINE($red_seq, 0)

WAITMS(300)
GETSCREEN
IF_PICTURE_IN(493,368, 498,374, "green.bmp")
    green()
ELSE
    IF_PICTURE_IN(493,368, 498,374, "red.bmp")
        INC($red_seq)
        IF($red_seq >= $N)
            green()
            $red_seq = 0
        ELSE
            red()
        END_IF
    END_IF
END_IF

Кстати, IF_PICTURE_IN там не нужен, можно просто проверять один пиксел в определённой точке.
Примерно так:
Code: (clickermann) [Select]
GETSCREEN(495, 370, 495, 370)
$px = PXL(495, 370)
IF($px = 3407667)
    // зелёный
END_IF
IF($px = 255)
    // красный
END_IF
Цвета и координаты свои.
« Last Edit: November 19, 2019, 11:05:39 AM by Vint »


d2_bot

  • Освоившийся
  • **
  • Posts: 85
    • View Profile
Спасибо огромное за крутейший скрипт))  ;)

dramster

  • Герой форума
  • *****
  • Posts: 1134
    • View Profile
Так скрипт то там и не нужен совсем, разберись с самом приложении, там все настраивается под любые нужны. И удвоения, и смена HILO, и проценты даже можно добавлять при выигрышал или проигрышах, и лимиты проигрышей или выигрышей (это только то что я вспомнил, функционала там поболей). Все уже сделано для тебя, зачем чтото новое придумывать  ;D .

d2_bot

  • Освоившийся
  • **
  • Posts: 85
    • View Profile
Типа такого:

Цвета и координаты свои.


Только скрипт в этом месте продолжает выполнять как будто не видит условий

Code: [Select]

ELSE

        INC($red_seq)
        IF($red_seq >= $N)   - вот тут он не считает, продолжает делать х2 несмотря на то что подряд красное выпало больше чем указано
            green()
            $red_seq = 0
        ELSE
     

d2_bot

  • Освоившийся
  • **
  • Posts: 85
    • View Profile
Так скрипт то там и не нужен совсем, разберись с самом приложении, там все настраивается под любые нужны. И удвоения, и смена HILO, и проценты даже можно добавлять при выигрышал или проигрышах, и лимиты проигрышей или выигрышей (это только то что я вспомнил, функционала там поболей). Все уже сделано для тебя, зачем чтото новое придумывать  ;D .

их автоставки почему то проигрывают как ни крути все, уходят за лимиты, чужие настройки много раз разные пробовал в итоге все в минус

Vint

  • Супермодератор
  • Герой форума
  • *
  • Posts: 3935
  • Лечу куда хочу. cman 4.13.014x32, 4.14.003 W10
    • View Profile
Так они и твои уйдут в минус. В том и смысл.

А по поводу >= версия должна быть последняя.
В более ранних можно оставить только больше >


Viktor

  • Зашел в гости
  • *
  • Posts: 5
    • View Profile
Есть рабочий скрипт
Code: (clickermann) [Select]
//-----------------------------ПЕРЕМЕННЫЕ-------------
//-----------------------------Удвоить------------
$Udvoit_x=412
$Udvoit_y=599


//-----------------------------Минимум-----------
$sbros_x=446
$sbros_y=595


// окно Размер ставоки
$r_st_x=352
$r_st_x1=458
$r_st_y=622


// Поле профита
$green_x1=516
$green_y1=611
$green_x2=746
$green_y2=630
$green_color=3407667 //зеленая надпись
$green_color1=6711039  //красная надпись


$hide_x=564 //кнопка Меньше
//$hide_x=685//кнопка Больше
$hide_y=589


$povtor=20 // 20 повторов скрипта

$n_x=367  // Нехватает денег
$n_y=165  // Нехватает денег
$n_x1=891 // Нехватает денег
$n_y1=410 // Нехватает денег
$n_color= 3130362

//----------------------------ПРОГРАММА----------------
1:
LOGWRITE (" Начало ")
LCLICK($sbros_x,$sbros_y) 
2:
LOGWRITE ("Нажимаем кнопку ")
LCLICK($hide_x,$hide_y)   //кнопка Больше
GETSCREEN ($n_x,$n_y,$n_x1,$n_y1)
IF_PICTURE_IN ($n_x,$n_y,$n_x1,$n_y1, "Нехватает.bmp", -1, 100)
   GETSCREEN (($n_x,$n_y,$n_x1,$n_y1))
   IF_PIXEL_IN($n_x,$n_y,$n_x1,$n_y1, $n_color)
     
      WAITMS(100)
   END_IF
   
   LOGWRITE (" Стоп ")
   HALT
END_IF
WAIT(3)
GETSCREEN ($green_x1,$green_y1,$green_x2,$green_y2)
IF_PIXEL_IN($green_x1,$green_y1,$green_x2,$green_y2, $green_color)
   LOGWRITE ("вылезла зеленая надпись  ")
   //   WAITMS(50)
   INC($count,1)
   IF($count = $povtor) // 20 повторов скрипта
      LOGWRITE ("стоп")
      HALT // стоп
   END_IF
   GOTO(1) //начать чтение файла с начала
ELSE
   GETSCREEN  ($green_x1,$green_y1,$green_x2,$green_y2)
   IF_PIXEL_IN($green_x1,$green_y1,$green_x2,$green_y2, $green_color1)
      LOGWRITE ("вылезла красная надпись")
      GETSCREEN ($n_x,$n_y,$n_x1,$n_y1)
      IF_PICTURE_IN ($n_x,$n_y,$n_x1,$n_y1, "Нехватает.bmp", -1, 100)
         GETSCREEN (($n_x,$n_y,$n_x1,$n_y1))
         IF_PIXEL_IN($n_x,$n_y,$n_x1,$n_y1, $n_color)
           
            WAITMS(100)
         END_IF
         LOGWRITE (" Стоп ")
         HALT
      END_IF
      LCLICK($Udvoit_x,$Udvoit_y)
     
      GOTO(2)
   END_IF
   
END_IF